Synchronisieren mit posegege of clock

Question

Gibt es eine Möglichkeit zu fragen, ob die Simulation unter @(posedge clk) Ereignis neben der Verwendung eines benannten Ereignisses ist, die zur gleichen Zeit ausgelöst wird?

Mit folgendem Code, kann ich sicherstellen, dass ich nur am posedge eine Uhr Sachen tun:

module tb; 

    bit clk; 
    always #2 clk = ~clk; 

    event pos_clk; 


    always @(posedge clk) 
    -> pos_clk; 

    initial begin 
    // stuff happens 
    @(posedge clk); 
    $display("[%0d] @(posedge clk)", $time()); 

    // control is passed asynchronously to some task 
    // - since it's already at a posedge, it doesn't need to wait 
    some_task(); 

    // other stuff happens 
    #1; 
    $display("[%0d] #1", $time()); 

    // control is passed asynchronously to some task 
    // - since it's not at a posedge, it needs to catch the next one 
    some_task(); 

    $finish(); 
    end 

    task some_task(); 
    wait (pos_clk.triggered); 
    $display("[%0d] wait (pos_clk.triggered)", $time()); 
    // do relevant stuff 
    endtask 
endmodule 

Gibt es irgendeine andere Weise, die ich dies ohne das zusätzliche genannte Ereignis tun könnte?

Answer 1

Dies ist, was das ##0 Konstrukt hat (Abschnitt 14.11 Zyklus Verzögerung Siehe: ## der 1800-2012 LRM). Sie haben einen Standardtaktblock zu definieren, was bedeutet, dass Ihre Aufgabe innerhalb eines definiert wird module oder interface

module tb; 

    bit clk; 
    always #2 clk = ~clk; 

    default clocking cb @(posedge clk) 
    endclocking 

    initial begin 
    // stuff happens 
    @(cb) // when using clocking blocks, only use the clocking event 
    $display("[%0d] @(posedge clk)", $time()); 

    // control is passed asynchronously to some task 
    // - since it's already at a posedge, it doesn't need to wait 
    some_task(); 

    // other stuff happens 
    #1; 
    $display("[%0d] #1", $time()); 

    // control is passed asynchronously to some task 
    // - since it's not at a posedge, it needs to catch the next one 
    some_task(); 

    $finish(); 
    end 

    task some_task(); 
    ##0; 
    $display("[%0d] wait (pos_clk.triggered)", $time()); 
    // do relevant stuff 
    endtask 
endmodule 

Mein Rat wäre, auch nicht zu tun und einen Weg finden, um die Aktivierung von some_task synchron zu halten .