VBScript - Fehlerbehandlung verwenden

Question

Ich möchte VBScript verwenden, um Fehler abzufangen und sie zu protokollieren (dh bei Fehler "melde etwas") und dann die nächste Zeile des Skripts fortsetzen.

Zum Beispiel

 
On Error Resume Next 
'Do Step 1 
'Do Step 2 
'Do Step 3 

Wenn ein Fehler auftritt auf Schritt 1, ich will es, dass Fehler protokollieren (oder andere mit ihrem kundenspezifische Funktionen ausführt) werden dann im Schritt wieder aufnehmen 2. Ist das möglich? und wie kann ich es umsetzen?

EDIT: Kann ich so etwas tun?

 
On Error Resume myErrCatch 
'Do step 1 
'Do step 2 
'Do step 3 

myErrCatch: 
'log error 
Resume Next 

Answer 1

VBScript hat keine Ahnung von Werfen oder Ausnahmen zu kontrollieren, aber die Laufzeit bietet ein globales Err-Objekt, das die Ergebnisse der letzten Operation enthält ausgeführt. Sie müssen explizit überprüfen, ob die Err.Number-Eigenschaft nach jeder Operation nicht null ist.

On Error Resume Next 

DoStep1 

If Err.Number <> 0 Then 
    WScript.Echo "Error in DoStep1: " & Err.Description 
    Err.Clear 
End If 

DoStep2 

If Err.Number <> 0 Then 
    WScript.Echo "Error in DoStop2:" & Err.Description 
    Err.Clear 
End If 

'If you no longer want to continue following an error after that block's completed, 
'call this. 
On Error Goto 0 

Die "On Error Goto [label]" Syntax von Visual Basic und Visual Basic für Applikationen (VBA) unterstützt, aber VBScript diese Sprache Funktion nicht unterstützt, so dass Sie On Error verwenden müssen Resume Next als oben beschrieben.

Answer 2

Beachten Sie, dass On Error Resume Next nicht global festgelegt ist. Sie können Ihren unsicheren Teil des Codes z. B. in eine Funktion einfügen, die sofort unterbrochen wird, wenn ein Fehler auftritt, und diese Funktion von einem Sub aufrufen, das eine Präzedenzfall-OERN-Anweisung enthält.

ErrCatch() 

Sub ErrCatch() 
    Dim Res, CurrentStep 

    On Error Resume Next 

    Res = UnSafeCode(20, CurrentStep) 
    MsgBox "ErrStep " & CurrentStep & vbCrLf & Err.Description 

End Sub 

Function UnSafeCode(Arg, ErrStep) 

    ErrStep = 1 
    UnSafeCode = 1/(Arg - 10) 

    ErrStep = 2 
    UnSafeCode = 1/(Arg - 20) 

    ErrStep = 3 
    UnSafeCode = 1/(Arg - 30) 

    ErrStep = 0 
End Function