Was ist in Perl der richtige Weg für eine Unterklasse, um eine Methode in der Basisklasse umzubenennen?

Question

Ich hasse einfach wie CGI::Application 's Accessor für die CGI Objekt heißt query.

Ich möchte, dass meine Instanzklassen einen Accessor namens cgi verwenden können, um das Objekt CGI zu erhalten, das der aktuellen Instanz meiner -Unterklasse zugeordnet ist. Hier

ist ein in sich geschlossenes Beispiel dafür, was ich tue:

package My::Hello; 

sub hello { 
    my $self =shift; 
    print "Hello @_\n"; 
} 

package My::Merhaba; 

use base 'My::Hello'; 

sub merhaba { 
    goto sub { shift->hello(@_) }; 
} 

package main; 

My::Merhaba->merhaba('StackOverflow'); 

Dies funktioniert, wie ich denke, es sollte, und ich kann keine Probleme sehen (sagen wir, wenn ich von My::Merhaba erben wollte: Subklassen muss nichts über merhaba wissen).

Wäre es besser/richtigere gewesen

sub merhaba { 
    my $self = shift; 
    return $self->hello(@_); 
} 

Was sind die Vorteile/Nachteile von goto &NAME von Aliasing einen Methodennamen für den Zweck verwenden zu schreiben? Gibt es einen besseren Weg?

Hinweis: Wenn Sie einen Drang zu reagieren mit goto ist böse tun es nicht, weil diese Verwendung von Perl goto anders ist als das, was Sie im Kopf haben.

Answer 1

Ihr Ansatz mit goto ist der richtige, weil es sicherstellt, dass caller/wantarray und dergleichen ordnungsgemäß funktionieren.

würde ich Setup die neue Methode wie folgt aus:

sub merhaba { 
    if (my $method = eval {$_[0]->can('hello')}) { 
     goto &$method 
    } else { 
     # error code here 
    } 
} 

Oder wenn Sie die Vererbung nicht verwenden möchten, können Sie die neue Methode an das bestehende Paket von Ihrem Aufruf Code hinzu:

*My::Hello::merhaba = \&My::Hello::hello; 
    # or you can use = My::Hello->can('hello'); 

dann können Sie anrufen:

My::Hello->merhaba('StackOverflow'); 

und das gewünschte Ergebnis erhalten.

Jeder Weg würde funktionieren, die Vererbungsroute ist wartungsfreundlicher, aber das Hinzufügen der Methode zum vorhandenen Paket würde schnellere Methodenaufrufe zur Folge haben.

Edit:

Wie in den Kommentaren darauf hingewiesen, gibt es ein paar Fälle wurden die glob Zuordnung in Konflikt geraten mit Vererbung laufen wird, also, wenn Sie Zweifel haben, verwenden Sie die erste Methode (ein neues Verfahren in einem Teilpaket zu schaffen).

Michael Carman vorgeschlagen, beide Techniken in eine selbst Neudefinition Funktion kombiniert:

sub merhaba { 
    if (my $method = eval { $_[0]->can('hello') }) { 
     no warnings 'redefine'; 
     *merhaba = $method; 
     goto &merhaba; 
    } 
    die "Can't make 'merhaba' an alias for 'hello'"; 
} 

Answer 2

Sie können die Subroutinen alias durch die Symboltabelle zu manipulieren:

*My::Merhaba::merhaba = \&My::Hello::hello; 

Einige Beispiele here gefunden werden können.

Answer 3

Ich bin nicht sicher, was der richtige Weg ist, aber Adam Kennedy verwendet Ihre zweite Methode (dh ohne goto) in Method::Alias (click here to go directly to the source code).

Answer 4

Dies ist eine Art Kombination von Quick-n-Dirty mit einem Minimum an Indirection mit UNIVERSAL::can.

package My::Merhaba; 
use base 'My::Hello'; 
# ... 
*merhaba = __PACKAGE__->can('hello'); 

Und Sie werden ein Unter „Merhaba“ in diesem Paket, das My::Hello::hello Aliase genannt haben. Sie sagen einfach, dass was immer dieses Paket sonst unter dem Namen hello tun würde, kann es unter dem Namen merhaba tun.

Dies ist jedoch nicht ausreichend in der Möglichkeit, dass einige Code-Dekorator die Sub ändern, auf die *My::Hello::hello{CODE} verweist. In diesem Fall könnte Method::Alias der geeignete Weg sein, eine Methode zu spezifizieren, wie die Moleküle vermuten lassen.

Wenn es sich jedoch um eine ziemlich gut kontrollierte Bibliothek handelt, in der Sie sowohl die Eltern- als auch die Kindkategorie steuern, lautet die obige Methode slimmer.