Assembly - Zeichne einen Kreis

Question

Ich versuche jetzt einen Kreis in Assembly zu zeichnen, aber aus irgendeinem Grund funktioniert es nicht, DOSBox friert ein und ich kann nicht zu verstehen, warum. Außerdem erscheint der Kreis nicht auf dem Bildschirm. Ich habe den Großteil des Codes online gefunden und versuche, ihn zu benutzen und zu verstehen, was er tut, aber ich kann hier keine Fehler finden. Hier

ist der Code:

player1disccolor db 0Eh 
Player1Disc: 
    push 0a000h 
    pop es     
    mov dx, 20    
    mov di, 20    
    mov al, [player1disccolor]    
    mov bx, 30     
    call Player1Disc  
    mov ah, 0 
    int 10h      
    mov bp,0     
    mov si,bx     

Disc1:     
    call Set8pixels        
    sub bx,bp    
    inc bp     
    sub bx,bp     
    jg Disc2     
    add bx,si     
    dec si     
    add bx,si    

Disc2:     
    cmp si,bp    
    jae Disc1     
    ret 

Set8pixels:   
    call Set4pixels    

Set4pixels:   
    xchg bp,si    
    call Set2pixels    

Set2pixels: 
    neg si 
    push di 
    add di,si 
    add di,dx 
    mov [es:[di+bp]],al 
    sub di,bp 
    stosb 
    pop di 
    ret 

Dank an alle, die helfen.

Answer 1

Player1Disc: 
    push 0a000h 
    pop es     
    mov dx, 20    
    mov di, 20    
    mov al, [player1disccolor]    
    mov bx, 30     
    call Player1Disc 

Mit diesem letzten Befehl call Player1Disc der Code rekursiv und endlos selbst aufrufen, ohne nützlich etwas zu tun! Dies wird unweigerlich das Programm zum Absturz bringen.

---

Auch wenn der obige Fehler nicht dort die nächsten 2 Zeilen war, den Videomodus auf einen undefinierten Modus eingestellt würden, weil das AL-Register nicht korrekt eingestellt!

mov ah, 0 <= This is the BIOS SetVideoMode function 
int 10h 

Answer 2

Ich verstehe nicht, was Sie mit dem Programm getan haben, das Sie auf the other forum gefunden haben.
Dies ist, was ich von dort kopiert habe. Es ist so einfach wie nur möglich.

.MODEL TINY 
.286 
.CODE 
    ORG  100h 
Start: 
    mov  ax,13h 
    int  10h     ;mode 13h 
    push  0a000h 
    pop  es     ;es in video segment 
    mov  dx,160    ;Xc 
    mov  di,100    ;Yc 
    mov  al,04h    ;Colour 
    mov  bx,50    ;Radius 
    call  Circle    ;Draw circle 
    mov  ah,0 
    int  16h     ;Wait for key 
    mov  ax,3 
    int  10h     ;Mode 3 
    mov  ah,4ch 
    int  21h     ;Terminate 

;*** Circle 
; dx= x coordinate center 
; di= y coordinate center 
; bx= radius 
; al= colour 
Circle: 
    mov  bp,0    ;X coordinate 
    mov  si,bx    ;Y coordinate 
c00: 
    call  _8pixels   ;Set 8 pixels 
    sub  bx,bp    ;D=D-X 
    inc  bp     ;X+1 
    sub  bx,bp    ;D=D-(2x+1) 
    jg  c01     ;>> no step for Y 
    add  bx,si    ;D=D+Y 
    dec  si     ;Y-1 
    add  bx,si    ;D=D+(2Y-1) 
c01: 
    cmp  si,bp    ;Check X>Y 
    jae  c00     ;>> Need more pixels 
    ret 
_8pixels: 
    call  _4pixels   ;4 pixels 
_4pixels: 
    xchg  bp,si    ;Swap x and y 
    call  _2pixels   ;2 pixels 
_2pixels: 
    neg  si 
    push  di 
    add  di,si 
    imul  di,320 
    add  di,dx 
    mov  es:[di+bp],al 
    sub  di,bp 
    stosb 
    pop  di 
    ret 
END Start 

Um Ihre eigene Version halten Sie die komplette Kreis Verfahren zu korrigieren und mit call Circle nennen. Ich schlage weiter vor, dass Sie das ES Segmentregister innerhalb der Circle Prozedur einrichten, es ist eine robustere Art, Dinge zu tun.

Player1Disc: 
    mov dx, 20     ;CenterX 
    mov di, 20     ;CenterY 
    mov al, [player1disccolor] ;Color    
    mov bx, 30     ;Radius 
    call Circle 
    ... 
    ALL THE OTHER CODE YOU NEED 
    ... 
Circle: 
    push 0A000h 
    pop es     
    mov bp, 0     
    mov si, bx 
    ... 

---

Die Gründe, warum Ihre abgestürzt Original-Code bereits von Fifoernik