Ausblenden (Unterdrücken) Globale öffentliche Parameter-Dialogfeld (Modelica Dymola)

Question

Ich habe eine parameter, die immer aus anderen Parametern berechnet wird, und muss public sein, so dass es von anderen Komponentenmodellen in meinem Projekt verwendet werden kann. Grundsätzlich ist es ein globalparameter in einem Objekt sehr ähnlich dem Objekt TIL.SystemInformationManager.

Da es berechnet wird, ist es sinnlos, es in einem Dialogfeld anzuzeigen; und die Verwendung von annotation(dialog(enable=false)) kann zu Verwirrung und Frustration führen, weil der Benutzer es immer aus keinem guten Grund deaktiviert sieht.

Weil es public sein muss, kann ich das Schlüsselwort protected nicht verwenden.

Es kann nicht final sein, weil es vom Modell eingestellt wird, das es verwendet.

Zuletzt muss es eine parameter sein, und keine Variable, weil ich es verwende, um ein Array zu dimensionieren.

Hier ist das Modell. Die Idee ist, dass in sim2 Sie den Anschlusstyp ct gesetzt, die dann n des Arrays der Größe berechnet myArray, die in allen Verbinderkomponenten verwendet:

package VerySimpleSIM 

    model Sim2 

    parameter Integer ct = 0 "Connector type"; 
    final parameter Integer n = if (ct > 0) then 2 else 0; 

    end Sim2; 

    connector MyConnector "Connector with array size set by global parameter n" 

    //~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 
    //This parameter is always set by the component using the connector, 
    //so I don't want to show it in any dialog box. 
    parameter Integer n; 
    //~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~ 

    Real myArray[n]; 

    end MyConnector; 

    model Creator 

    protected 
    outer Sim2 sim2 "System information manager"; 

    public 
    MyConnector cnctrB(final n=sim2.n) annotation (Placement(transformation(extent={{80,-10},{100,10}}))); 

    equation 
    //Create arbitrary values for testing: time + 0.1 * {1,2,...,n} 
    cnctrB.myArray = {time + 0.1 * i for i in 1:sim2.n}; 
    end Creator; 

    model Changer 

    protected 
    outer Sim2 sim2 "System information manager"; 

    public 
    MyConnector cnctrA(final n=sim2.n) annotation (Placement(transformation(extent={{-100,-10},{-80,10}}))); 
    MyConnector cnctrB(final n=sim2.n) annotation (Placement(transformation(extent={{80,-10},{100,10}}))); 

    equation 
    //Output = sin(2 * pi * input) 
    cnctrB.myArray = Modelica.Math.sin(2 * Modelica.Constants.pi .* cnctrA.myArray); 
    end Changer; 

    model TestSim2 

    inner Sim2 sim2(ct=1) annotation (Placement(transformation(extent={{20,20},{40,40}}))); 

    Changer changer annotation (Placement(transformation(extent={{-10,-10},{10,10}}))); 
    Creator creator annotation (Placement(transformation(extent={{-40,-10},{-20,10}}))); 
    equation 
    connect(creator.cnctrB, changer.cnctrA) annotation (Line(points={{-21,0},{-9,0}})); 
    annotation (Icon(coordinateSystem(preserveAspectRatio=false)), Diagram(coordinateSystem(preserveAspectRatio=false))); 
    end TestSim2; 
end VerySimpleSIM; 

Answer 1

Verwenden annotation(dialog(connectorSizing=true)) in einem Dialogfeld zeigt einen Parameter zu unterdrücken. Zum Beispiel die Zeile, die liest,

parameter Integer n; 

zu lesen,

parameter Integer n annotation(dialog(connectorSizing=true)); 

Answer 2

Sie zeigen/ausblenden, um einen Parameter, um die public und protected Schlüsselwörter wie im folgenden Beispiel gezeigt:

model protectedParameter 
    parameter Real p1=1 "Visible parameter"; 
    parameter Real p2=3.14 "another visible parameter"; 
protected 
    parameter Real derivedParameter=p1+p2+p3 "Hidden (protected) parameter"; 
public 
    parameter Real p3=2.71 "yet another visible parameter"; 
equation 
    // equations from here on 
    ... 
end protectedParameter; 

Alternativ können Sie das Schlüsselwort final vor die Parameterdeklaration stellen, und Dymola wird es zumindest vor den Dialogen verbergen.

Mit freundlichen Grüßen, Rene Gerade Nielsen