Wie kann ich ein Passwort mit Perl eingeben und die Zeichen durch '*' ersetzen?

Question

Ich habe ein Perl-Skript, das erfordert, dass der Benutzer ein Kennwort eingibt. Wie kann ich an Stelle des Zeichens, das der Benutzer beim Eintippen eingibt, nur '*' ausgeben?

Ich benutze Windows XP/Vista.

Answer 1

Sie können mit Term :: ReadKey spielen. Hier ist ein sehr einfaches Beispiel mit einer Erkennung für Rücktaste und Löschtaste. Ich habe es auf Mac OS X 10.5 getestet, aber laut der ReadKey manual sollte es unter Windows funktionieren. Die manual zeigt an, dass unter Windows nicht blockierende Lesevorgänge (ReadKey(-1)) fehlschlagen. Deshalb benutze ich ReadKey (0), der im Grunde getc ist (mehr auf getc in libc manual).

#!/usr/bin/perl                                                 

use strict;                                                  
use warnings;                                                 
use Term::ReadKey;                                                

my $key = 0;                                                 
my $password = "";                                                

print "\nPlease input your password: ";                                           

# Start reading the keys                                              
ReadMode(4); #Disable the control keys                                           
while(ord($key = ReadKey(0)) != 10)                                            
# This will continue until the Enter key is pressed (decimal value of 10)                                  
{                                                    
    # For all value of ord($key) see http://www.asciitable.com/                                     
    if(ord($key) == 127 || ord($key) == 8) {                                         
     # DEL/Backspace was pressed                                            
     #1. Remove the last char from the password                                        
     chop($password);                                              
     #2 move the cursor back by one, print a blank character, move the cursor back by one                             
     print "\b \b";                                               
    } elsif(ord($key) < 32) {                                             
     # Do nothing with these control characters                                        
    } else {                                                 
     $password = $password.$key;                                            
     print "*(".ord($key).")";                                            
    }                                                   
}                                                    
ReadMode(0); #Reset the terminal once we are done                                        
print "\n\nYour super secret password is: $password\n"; 

Answer 2

Haben Sie versucht, die Zeichenfolge zu speichern (so dass Ihr Programm es immer noch lesen kann) und seine Länge zu ermitteln, dann erstellen Sie eine Zeichenfolge der gleichen Länge, aber verwenden Sie nur '*'?

Answer 3

Sie sollten sich entweder Term::ReadKey oder Win32::Console ansehen. Sie können diese Module verwenden, um die einzelnen Tastenanschläge zu lesen und '*' oder was auch immer auszugeben.

Answer 4

In der Vergangenheit habe ich IO::Prompt zum Einsatz.

use IO::Prompt; 
my $password = prompt('Password:', -e => '*'); 
print "$password\n"; 

Answer 5

Wenn Sie keine Pakete verwenden möchten ... Nur für UNIX

system('stty','-echo'); 
chop($password=<STDIN>); 
system('stty','echo'); 

Answer 6

Aufbauend auf Pierr-Luc Programm, haben soeben eine gewisse Kontrolle über die Schrägstriche. Damit können Sie nicht für immer Backslash drücken:

sub passwordDisplay() { 
    my $password = ""; 
    # Start reading the keys 
    ReadMode(4); #Disable the control keys 
    my $count = 0; 
    while(ord($key = ReadKey(0)) != 10) { 
      # This will continue until the Enter key is pressed (decimal value of 10) 
      # For all value of ord($key) see http://www.asciitable.com/ 
      if(ord($key) == 127 || ord($key) == 8) { 
        # DEL/Backspace was pressed 
        if ($count > 0) { 
          $count--; 
          #1. Remove the last char from the password 
          chop($password); 
          #2 move the cursor back by one, print a blank character, move the cursor back by one 
          print "\b \b"; 
        } 
      } 
      elsif(ord($key) >= 32) { 
        $count++; 
        $password = $password.$key; 
        print "*"; 
      } 
    } 
    ReadMode(0); #Reset the terminal once we are done 
    return $password; 
}