VBA UDF ändert Werte auf ALLEN Blättern. Wie kann man auf eins beschränken?

Question

Ich habe eine UDF erstellt, die auf einem einzigen Blatt funktioniert. Das Problem tritt bei mehreren Blättern auf. Wenn ich die Formel auf mehreren Blättern habe und wenn ich sie auf ein Blatt (neu) lade, ändert sich auch die Ausgabe in ALLE anderen Blätter.

Warum passiert das? Ich verwende kein ActiveWorksheet oder Active Cell oder ähnliches.

Function customreturn(security As Range, datacheck As Range) As Variant 

    Dim row_num As Integer 
    Dim row_num2 As Integer 
    Dim price1 As Double 
    Dim price2 As Double 
    Dim perfo As Double 
    Dim blank_end As Boolean 

    row_num = security.Row 
    col_num = security.Column 
    row_num2 = row_num + 1 
    col_num2 = datacheck.Column 

    If WorksheetFunction.IsError(datacheck.Value) = True Then 
     customreturn = "No data" 
    Else 
     price1 = Cells(row_num, col_num).Value 

     Do While WorksheetFunction.IsError(Cells(row_num2, col_num2).Value) = True 
      row_num2 = row_num2 + 1 
     Loop 

     price2 = Cells(row_num2, col_num).Value 

     perfo = price1/price2 - 1 

     customreturn = perfo 
    End If 
End Function 

Answer 1

Es gibt keine übergeordnete Arbeitsblatt für jede der drei Mal angegeben Sie die Range.Cells property so die Mutter Arbeitsblatt verwenden wird dem ActiveSheet property Verzug geraten. Dies kann mit einer With ... End With statement behoben werden, die einen Arbeitsblattverweis auf einen der Bereichsparameter 'Range.Parent property bietet.

Function customreturn(security As Range, datacheck As Range) As Variant 
    Dim row_num As Long, row_num2 As Long, col_num As Long, col_num2 As Long 
    Dim price1 As Double, price2 As Double, perfo As Double 
    Dim blank_end As Boolean 

    row_num = security.Row 
    col_num = security.Column 
    row_num2 = row_num + 1 
    col_num2 = datacheck.Column 

    With security.Parent 
     If IsError(datacheck) Then 
      customreturn = "No data" 
     Else 
      price1 = .Cells(row_num, col_num).Value 

      Do While IsError(.Cells(row_num2, col_num2)) 
       row_num2 = row_num2 + 1 
      Loop 

      price2 = .Cells(row_num2, col_num).Value 

      perfo = price1/price2 - 1 

      customreturn = perfo 
     End If 
    End With 
End Function 

Im With ... End With, die alle die Cells sind Referenzen als .Cells zu zeigen, dass das übergeordnete Arbeitsblatt derjenige in der mit Bezug genommen wird, ... End With.

Sie müssen die ISERROR- oder VBA-Werte des Arbeitsblatts IsError function nicht unbedingt mit True vergleichen. Es weiß bereits, ob es wahr oder falsch ist.

Es wurde darauf hingewiesen (danke BruceWayne), dass Sie zwei nicht deklarierte Variablen, col_num und col_num2 hatten. Dies kann vermieden werden, indem Sie Option Explicit¹ oben im Codeblatt im Deklarationsbereich hinzufügen.

---

¹ _{Einstellung Variablendeklaration erforderlich innerhalb der Werkzeuge des VBE ► Optionen ► Editor Eigenschaftenseite der Option Explicit Anweisung an den Anfang jedes neu erstellten Code Blatt gelegt wird. Dies vermeidet alberne Codierungsfehler wie Rechtschreibfehler und beeinflusst Sie, den richtigen Variablentyp in der Variablendeklaration zu verwenden. Variablen, die ohne Deklaration direkt erstellt werden, sind alle vom Typ Variante/Objekt. Verwenden Option Explicit ist weithin als "Best Practice".}