Ist es möglich, eine SPARQL DELETE {} WHERE {} mit einem FILTER (COUNT (DISTINCT? Obj)> x) in der WHERE-Klausel zu machen?

Question

Ich möchte eine Löschung erreichen, die alle Tripel löscht, wenn weniger als x verschiedene Objekte pro Subjekt vorhanden sind.

Die beabsichtigte Abfrage sollte so etwas wie dies nach meinem Gefühl aussehen:

DELETE { ?sub ?pred ?obj . } 
WHERE { 
    {SELECT ?sub ?pred ?obj (count(?obj) as ?count) 
    WHERE { ?sub ?pred ?obj . 
     } GROUP BY ?sub 
    } FILTER(?count < 14) 
} 

Die oben funktioniert nicht.

Auch eine GROUP BY ist notwendig, um die ?obj pro ?sub Teil zu erreichen, aber ich kann mir nicht vorstellen, wie dies zu tun ist.

Kann mich jemand in die richtige Richtung drängen, um diese Aufgabe zu lösen?

Answer 1

Beachten Sie, dass Ihre Unterabfrage keine gültige Abfrage ist. Wenn Sie versuchen, nur die Unterabfrage auf sparql.org's query validator zu überprüfen, erhalten Sie diese Ausgabe:

Syntax error:

Non-group key variable in SELECT: ?pred

Merkwürdigerweise, obwohl die ganze Abfrage tut Validieren mit dem update validator. Es ist nicht ganz klar von Ihrer versuchten Abfrage, was genau Sie versuchen zu löschen, und die Aussage:

I want to achieve a delete which deletes all triples where there are less than x distinct objects per subject.

macht es auch nicht vollkommen klar. Wenn Sie versuchen, Tripel mit einem Thema zu löschen, die weniger als 10 verschiedene Objekte über alle die Prädikate mit diesem Thema verwendet verwandt ist, würden Sie sie wie diese finden:

select ?s ?p ?o { 
    ?s ?p ?o 
    { select ?s { ?s ?pp ?oo } 
    group by ?s 
    having (count(distinct ?oo) < 10) } 
} 

Dann zu erweitern, um ein Löschen zu tun ist einfach:

delete { ?s ?p ?o } 
where { 
    ?s ?p ?o 
    { select ?s { ?s ?pp ?oo } 
    group by ?s 
    having (count(distinct ?oo) < 10) } 
}