Wie man hebräische Jahrestage definiert, um in Org-Agenda zu erscheinen?

Question

Wie werden hebräische Jahrestage (wie Geburtstage) in der Org Agenda angezeigt? Am besten wäre es über BBDB. Bisher habe ich es geschafft, Jubiläen/Geburtstage zu BBDB hinzuzufügen und sie in org-agenda anzuzeigen. Jetzt muss ich zum nächsten Schritt gehen und diese Daten als hebräische Daten angeben. Im Tagebuchmodus scheinen die Daten wie HSivan 17, 5776 zu sein. Aber wenn ich es in BBDB wie anniversary: HSivan 17, 5776 birthday einfügen - bekomme ich Fehler beim Versuch, Agenda-Sicht zu generieren: bad-sexp at line 5 /path/to/agenda.org (org-bbdb-anniversaries). Vielleicht gibt es andere Möglichkeiten (ohne BBDB), vielleicht kann ich sie direkt in einer .org-Datei auflisten?

Answer 1

Im Allgemeinen org-Modus befasst sich nicht gut (oder überhaupt) mit Kalendern anders als ISO-basierte, western Kalender. Wenn Sie unterschiedlich formatierte Daten in bbdb speichern möchten, können Sie org-bbdb-extract-date-fun anpassen. Sie müssen Ihre eigene Funktion schreiben, um hebräische Daten zu analysieren und zurückzugeben (Monat Tag Jahr).

Damit können Sie eine bbdb-Datenbank mit hebräischen Daten verwenden, aber es wird nicht vorhanden, z. B. Agenda Ausgabe mit hebräischen Daten. Das ist ein viel schwierigeres Problem, insbesondere weil die ISO-Kalenderannahme die Code-Basis des Organisationsmodus durchdringt.

EDIT: Hier ist eine Funktion, die eine Zeichenfolge wie „Heshvan 17, 5776“ nimmt als Argument und erzeugt ein (Monat, Tag, Jahr) tuple dass org verwenden:

;;; This function uses functions and variables defined in calendar.el 
;;; and cal-hebrew.el 

(require 'calendar) 
(require 'cal-hebrew) 

(defun org-bbdb-anniv-extract-hebrew-date (date-string) 
    "Parse the string, assumed to be in the form \"MONTHNAME day, 
    year\", using Hebrew month names. Day is an integer, roughly 
    between 1 and 30 (the range depends on the month and the 
    year), and year is an integer representing a Hebrew calendar 
    year (roughly 5776 ~= 2015)." 
    (let* ((date-list (split-string date-string)) 
      (month-name (nth 0 date-list)) 
      (day (string-to-number (nth 1 date-list))) 
      (year (string-to-number (nth 2 date-list))) 
      (month-array (if (calendar-hebrew-leap-year-p year) 
          calendar-hebrew-month-name-array-leap-year 
          calendar-hebrew-month-name-array-common-year)) 
      (month (cdr (assoc-string 
         month-name 
         (calendar-make-alist month-array 1))))) 
     (calendar-gregorian-from-absolute 
     (calendar-hebrew-to-absolute (list month day year))))) 

;; test: (org-bbdb-anniv-extract-hebrew-date "Heshvan 17, 5776") ==> (10 30 2015) 
;; test: (org-bbdb-anniv-extract-hebrew-date "Heshvan 17, 3762") ==> (10 22 1) 
;; I hope these are right. 

;; To get org-bbdb to use this function to read dates from the BBDB 
;; database, instead of the standard org-bbdb-anniv-extract-date, do 
;; this: 

;; (setq org-bbdb-extract-date-fun #'org-bbdb-anniv-extract-hebrew-date) 

;; N.B. *ALL* dates in the BBDB database will be read using this 
;; function, so *ALL* of them must be Hebrew calendar dates. There is 
;; no provision for dates in different formats. To do that, one would 
;; need to write a function that can recognize dates in different 
;; formats (probably using heuristics) and then call the right 
;; conversion function. That's beyond the scope of this answer. 

;; Also, calendrical calculations are notoriously difficult to get 
;; right: this is no exception. In particular, the month calculation 
;; is probably valid only for dates in the Common Era, i.e. for years 
;; >= 3762. cal-hebrew.el has more details. But in any case, no 
;; guarantees: if it breaks, you get to keep the pieces. 

Answer 2

Ich glaube, Sie bbdb Problem durch diese Umsetzung in Ihrem .emacs beheben können:

(require 'org-bbdb)