Korrekte Formel gibt "Laufzeitfehler '1004': Anwendungsdefiniert oder objektdefiniert" Fehler beim Ausführen von Sub

Question

Ich möchte Formeln in Spalte B mit einer Verzögerung dazwischen einfügen. Die Formel sollte nur die Formel einfügen, wenn die Zelle, um es nach links (im Fall von B1 ist das A1) nicht leer ist, wie folgt aus:

Ich habe folgende VBA, die die Formel mit einer Verzögerung Pasten von 1 Sek.

Option Explicit 

Sub RetrieveDataDelay() 
'paste formulas into cells, then calculate, then delay rinse repeat 

    '========================= 
    'Declare Variables 
    '========================= 
     Dim i As Long 'used to loop 
     Dim rowCount As Long 
     Dim LastRow As Long 'used to find the last row 

    '========================= 
    'Setup for Speed 
    '========================= 
     Application.ScreenUpdating = False 
     Application.Calculation = xlCalculationManual 

    '========================= 
    'Define Variables 
    '========================= 
     LastRow = Worksheets(ActiveSheet.Name).Cells(Rows.Count, 1).End(xlUp).Row 'This will find the last used row in column A, change the number 1 to whatever column number you want 
     rowCount = 1 ' set to how many rows you want to do at a time 

    '========================= 
    'Do Work 
    '========================= 
     For i = 1 To LastRow Step rowCount 
      Range("B" & i, "B" & WorksheetFunction.Min(i + rowCount - 1, LastRow)).Formula = "'=IF(ISBLANK(A" & i & ");" & """" & """" & ";Dump(Volumes(A" & i & ";2528;1010;TRUE;" & "Volume" & ";TRUE)))" 'set the formula to whatever it needs to be 
       Calculate 
        Application.Wait (Now + TimeValue("00:00:01")) 'this delays 1 second 
     Next i 

    '========================= 
    'Setup for Speed - Reverse 
    '========================= 
     Application.ScreenUpdating = True 
     Application.Calculation = xlCalculationAutomatic 

End Sub 

Der Fehler tritt bei diesem Teil

Range("B" & i, "B" & WorksheetFunction.Min(i + rowCount - 1, LastRow)).Formula = "=IF(ISBLANK(A" & i & ");" & """" & """" & ";Dump(Volumes(A" & i & ";2528;1010;TRUE;" & "Volume" & ";TRUE)))" 

Die Fehler hat etwas mit der Formel zurückzuführen, die es nicht akzeptiert. Dies ist eine benutzerdefinierte Formel, die mit einer Excel-Erweiterung verwendet wird. Ich weiß, dass die Formel funktioniert, wie ich ein einfaches Anführungszeichen vor als solche setzen:

Range("B" & i, "B" & WorksheetFunction.Min(i + rowCount - 1, LastRow)).Formula = "'=IF(ISBLANK(A" & i & ");" & """" & """" & ";Dump(Volumes(A" & i & ";2528;1010;TRUE;" & "Volume" & ";TRUE)))" 

so dass es die formal buchstäblich Pasten. Wenn ich dann das Anführungszeichen aus der Formel entferne, funktioniert die Formel. Es bleibt also die Frage, warum es diese spezielle Formel in der VBA nicht akzeptiert.

Mit Excel 2013

Answer 1

Range.Formula braucht die Formel Notation immer in en_us Format unabhängig von den aktuellen Locale-Einstellungen. Das bedeutet Funktionen in englischer Sprache und auch Komma als Trennzeichen zwischen Formelparametern und nicht Semikolon.

So

.Formula = "=IF(ISBLANK(A" & i & ")," & """" & """" & ",Dump(Volumes(A" & i & ",2528,1010,TRUE," & "Volume" & ",TRUE)))" 

Nach Range.Formula Einstellung werden die lokalen Einstellungen in dem Blatt dennoch aktiv sein. In diesem Fall wird die Formel mit einem Semikolon abgegrenzt.

Bt .: Die komplizierte String-Notation für doppelte Anführungszeichen ist nicht notwendig.

.Formula = "=IF(ISBLANK(A" & i & "),"""",Dump(Volumes(A" & i & ",2528,1010,TRUE," & "Volume" & ",TRUE)))"