Erhalte den Wochentag in SQL 2005/2008

Question

Wenn ich ein Datum 01/01/2009 habe, möchte ich herausfinden, welcher Tag es war z. Montag, Dienstag, etc ...

Gibt es dafür in SQL 2005/2008 eine eingebaute Funktion? Oder muss ich einen Hilfstisch verwenden?

Answer 1

Verwenden DATENAME oder DATEPART:

SELECT DATENAME(dw,GETDATE()) -- Friday 
SELECT DATEPART(dw,GETDATE()) -- 6 

Answer 2

Obwohl SQLMenace Antwort ist, akzeptiert es ist eine wichtige SET Option

bewusst

SET DATEFIRST

DATENAME werden sollte, korrektes Datum zurückgeben Name aber nicht gleich DATEPART Wert, wenn der erste Wochentag wie unten dargestellt geändert wurde.

declare @DefaultDateFirst int 
set @DefaultDateFirst = @@datefirst 
--; 7 First day of week is "Sunday" by default 
select [@DefaultDateFirst] = @DefaultDateFirst 

set datefirst @DefaultDateFirst 
select datename(dw,getdate()) -- Saturday 
select datepart(dw,getdate()) -- 7 

--; Set the first day of week to * TUESDAY * 
--; (some people start their week on Tuesdays...) 
set datefirst 2 
select datename(dw,getdate()) -- Saturday 
--; Returns 5 because Saturday is the 5th day since Tuesday. 
--; Tue 1, Wed 2, Th 3, Fri 4, Sat 5 
select datepart(dw,getdate()) -- 5 <-- It's not 7! 
set datefirst @DefaultDateFirst 

Answer 3

Um einen deterministischen Wert für den Tag der Woche für ein bestimmtes Datum erhalten Sie eine Kombination aus DATEPART() und @@datefirst nutzen könnten. Ansonsten sind Sie auf die Einstellungen auf dem Server angewiesen.

Überprüfen Sie die folgende Website für eine bessere Lösung aus: MS SQL: Day of Week

Der Tag der Woche wird dann im Bereich von 0 bis 6, wobei 0 Sonntag, 1 Montag, usw. Dann können Sie ein verwenden einfache case-Anweisung, um den korrekten Wochentagnamen zurückzugeben.

Answer 4

SELECT CASE DATEPART(WEEKDAY,GETDATE()) 
    WHEN 1 THEN 'SUNDAY' 
    WHEN 2 THEN 'MONDAY' 
    WHEN 3 THEN 'TUESDAY' 
    WHEN 4 THEN 'WEDNESDAY' 
    WHEN 5 THEN 'THURSDAY' 
    WHEN 6 THEN 'FRIDAY' 
    WHEN 7 THEN 'SATURDAY' 
END 

Answer 5

dies ist eine Arbeitskopie von meinem Code überprüfen Sie es, wie in SQL-Tag Name von Datum retrive

CREATE Procedure [dbo].[proc_GetProjectDeploymentTimeSheetData] 
@FromDate date, 
@ToDate date 

As 
Begin 
select p.ProjectName + ' (' + st.Time +' '+'-'+' '+et.Time +')' as ProjectDeatils, 
datename(dw,pts.StartDate) as 'Day' 
from 
ProjectTimeSheet pts 
join Projects p on pts.ProjectID=p.ID 
join Timing st on pts.StartTimingId=st.Id 
join Timing et on pts.EndTimingId=et.Id 
where pts.StartDate >= @FromDate 
and pts.StartDate <= @ToDate 
END 

Glücklich Codierung ....

Answer 6

Sie können diese Version nützlich finden .

-- Test DATA 
select @@datefirst 
create table #test (datum datetime) 
insert #test values ('2013-01-01') 
insert #test values ('2013-01-02') 
insert #test values ('2013-01-03') 
insert #test values ('2013-01-04') 
insert #test values ('2013-01-05') 
insert #test values ('2013-01-06') 
insert #test values ('2013-01-07') 
insert #test values ('2013-01-08') 
-- Test DATA 

select Substring('Sun,Mon,Tue,Wed,Thu,Fri,Sat,Sun,Mon,Tue,Wed,Thu,Fri,Sat', 
     (DATEPART(WEEKDAY,datum)+@@datefirst-1)*4+1,3),Datum 
     from #test 

Answer 7

EUROPA:

declare @d datetime; 
set @d=getdate(); 
set @dow=((datepart(dw,@d) + @@DATEFIRST-2) % 7+1); 

Answer 8

Mit SQL Server 2012 und weiter können Sie die Verwendung FORMAT Funktion

SELECT FORMAT(GETDATE(), 'dddd') 

Answer 9

Wenn Sie möchten, auf @@DATEFIRST nicht hängen oder DATEPART(weekday, DateColumn) zu bedienen, einfach Berechnen Sie den Wochentag selbst.

Für Montag basierend Wochen (Europe) einfachste ist:

SELECT DATEDIFF(day, '17530101', DateColumn) % 7 + 1 AS MondayBasedDay 

Für Sonntag basierte Wochen (Amerika) verwenden:

SELECT DATEDIFF(day, '17530107', DateColumn) % 7 + 1 AS SundayBasedDay 

Diese Rückkehr der Wochentag Nummer (1 bis 7), seit Januar 1. bzw. 7., 1753.