Wie kann ich Sitzungsdaten zwischen Dancer2-Apps mit verschiedenen Serialisern teilen?

Question

Ich versuche eine App von Dancer zu Dancer2 zu migrieren. Mein Gedanke ist, den Code in Routen zu trennen, die mit Vorlagen und solchen, die Ajax (API) -Aufrufe sind, bedient werden.

Meine Basis-App ist:

use strict; 
use warnings; 
use FindBin; 
use Plack::Builder; 

use Routes::Templates; 
use Routes::Login; 

builder { 
    mount '/' => Routes::Templates->to_app; 
    mount '/api' => Routes::Login->to_app; 
}; 

Ich dachte, dass das Routes::Templates Paket keine Serializer haben würde und das Routes::Login Paket würde JSON Serialisierung haben. Ich verwendete

set serializer => 'JSON'; 

im Routes::Login Paket.

Allerdings möchte ich auch diese Session-Daten teilen, so dass jeder eine gemeinsame appname hat

use Dancer2 appname => 'myapp'; 

in jeder Datei. Und das scheint Probleme mit der Serialisierung zu haben. Die Routes::Template Routen werden nicht korrekt zurückgegeben, da versucht wird, sie als JSON zu codieren. Hier ist der Fehler:

Failed to serialize content: hash- or arrayref expected (not a simple scalar, use allow_nonref to allow this)

ich alle Unterlagen gelesen haben, darunter diese:

• How can I use Dancer2::Plugin::Database when my code is split into multiple files?
• https://github.com/wyoung/advent-calendar/tree/master/danceradvent/public/articles/2015

Aber ich bin immer noch nicht klar, wie die Serializer ist durch Paket getrennt.

Answer 1

Sie müssen Ihre Apps nicht mit appname kombinieren; Sitzungsdaten werden freigegeben, solange beide Apps dieselbe Konfiguration für die Sitzungs-Engine verwenden. (. Auch serializers are an all-or-nothing prospect in Dancer2, so dass Sie wirklich haben zwei getrennte Anwendungen zu verwenden)

Hier ist das Beispiel, das ich gab auf dem dancer-users mailing list:

MeineAnw/lib/MyApp.pm

package MyApp; 
use Dancer2; 

our $VERSION = '0.1'; 

get '/' => sub { 
    session foo => 'bar'; 
    template 'index'; 
}; 

true; 

MeineAnw/lib/MyApp/API.pm

package MyApp::API; 
use Dancer2; 

set serializer => 'JSON'; 

get '/' => sub { 
    my $foo = session('foo') // 'fail'; 
    return { foo => $foo }; 
}; 

true; 

MeineAnw/bin/app.psgi

#!/usr/bin/env perl 

use strict; 
use warnings; 
use FindBin; 
use lib "$FindBin::Bin/../lib"; 

use MyApp; 
use MyApp::API; 
use Plack::Builder; 

builder { 
    mount '/' => MyApp->to_app; 
    mount '/api' => MyApp::API->to_app; 
}; 

Wenn Sie die / Route durch die im gleichen Browser /api Route gefolgt zugreifen, werden Sie

{"foo":"bar"} 

darauf hinweist, dass die gleiche Sitzung erhalten Variable wurde von beiden Anfragen verwendet.