JSON zu Hash machen, dann diesen Hash mit einem anderen Hash in Perl vergleichen

Question

Ich habe 2 Dateien (JSON-Datei und PID-Datei). Das Format für die JSON-Datei ist:

{ 
"connection": { 
    "file": { 
    "file_connection_1": { 
    "CLOUD_AUTHENTICATION": "", 
    "CLOUD_CONN_PROTOCOL": "", 
    "CONN_NAME": "file_connection_1", 
    "FILE_DIR": "/home/directory" 
    } 
    } 
} 
} 

Format für pid:

<General> 
"CLOUD_AUTHENTICATION": "YES" 
"CLOUD_CONN_PROTOCOL": "PRTCL" 
"CONN_NAME": "file_connection_1" 
"FILE_DIR": "/home/directory" 
</General> 

ich beide die Dateien in Hashes konvertieren möchten, und dann die Werte der Schlüssel vergleichen (zB CLOUD_AUTHENTICATION oder CLOUD_CONN_PROTOCOL ... .). Nimm die Werte von pid und füge sie in den JSON-Datei-Hash ein, falls nicht vorhanden. Ich bin in der Lage, die Dateien in Hash zu konvertieren, aber nicht klar darüber, wie Sie die Schlüssel vergleichen und den Wert von PID-Hash auf JSON-Hash kopieren.

Answer 1

Die Art, wie ich die Frage verstehe, haben Sie zwei Hashes, die die gleichen Schlüssel haben. Wenn der erste Wert keinen Wert für einen bestimmten Schlüssel hat, möchten Sie den Wert aus dem anderen Hash dorthin setzen.

Weil Sie nicht angegeben haben, wie Sie diese Hashes erstellen, habe ich meine eigene Lösung dafür gefunden. Sie können es wahrscheinlich ignorieren. Ich benutzte Config::General und einige Tricks, um " und : loszuwerden, um die pid-Datei und JSON für den JSON zu lesen.

use strict; 
use warnings; 
use Config::General; 
use JSON 'decode_json'; 
use Data::Dumper; 

# read the pid file 
my %cfg_pid = Config::General->new(
    -NormalizeOption => sub { my $x = shift; $x =~ s/^"|":$//g; $x; }, 
    -NormalizeValue => sub { my $x = shift; $x =~ s/^"|"$//g; $x }, 
    -ConfigFile  => \*DATA 
)->getall; 

# read the json file 
my $json = <<'JSON'; 
{ 
"connection": { 
    "file": { 
    "file_connection_1": { 
    "CLOUD_AUTHENTICATION": "", 
    "CLOUD_CONN_PROTOCOL": "", 
    "CONN_NAME": "file_connection_1", 
    "FILE_DIR": "/home/directory" 
    } 
    } 
} 
} 
JSON 

my $cfg_json = decode_json($json); 

# this is before 
print Dumper $cfg_json; 

# actual part that you want 
foreach my $key (keys %{ $cfg_pid{General} }) { 
    $cfg_json->{connection}->{file}->{file_connection_1}->{$key} = $cfg_pid{General}->{$key} 
     unless $cfg_json->{connection}->{file}->{file_connection_1}->{$key}; 
} 

# and this is after 
print Dumper $cfg_json; 

__DATA__ 
<General> 
"CLOUD_AUTHENTICATION": "YES" 
"CLOUD_CONN_PROTOCOL": "PRTCL" 
"CONN_NAME": "file_connection_1" 
"FILE_DIR": "/home/directory" 
</General> 

Alles, was es wirklich ist den Schlüssel des pid Dateihash tut laufen, und aktivieren Sie im json Hash, wenn es ein Wert dieses Schlüssels ist. Wenn dieser Wert nicht wahr ist (dh der Schlüssel existiert nicht, der Wert ist undef, ein leerer String q{} oder), wird er auf den Wert des PID-Hashes gesetzt. Sie können natürlich auch explizit nach leeren Zeichenketten suchen.

Der Ausgang ist wie folgt.

$VAR1 = { 
    'connection' => { 
     'file' => { 
      'file_connection_1' => { 
       'FILE_DIR'    => '/home/directory', 
       'CONN_NAME'   => 'file_connection_1', 
       'CLOUD_CONN_PROTOCOL' => '', 
       'CLOUD_AUTHENTICATION' => '' 
      } 
     } 
    } 
}; 
$VAR1 = { 
    'connection' => { 
     'file' => { 
      'file_connection_1' => { 
       'FILE_DIR'    => '/home/directory', 
       'CONN_NAME'   => 'file_connection_1', 
       'CLOUD_CONN_PROTOCOL' => 'PRTCL', 
       'CLOUD_AUTHENTICATION' => 'YES' 
      } 
     } 
    } 
};