Aufruf der ActionScript-Funktion von JS

Ich würde mich über jede Hilfe bei diesem Problem freuen.Aufruf der ActionScript-Funktion von JS

Ich versuche, eine AS-Funktion auszuführen, wenn ein bestimmter Link angeklickt wird, aber ich kann es nicht funktionieren. Ich verwende den Code wie folgt:

In meinem Objektkonstruktor, ich habe die folgende Zeile ein:

ExternalInterface.addCallback("methodName",methodName);

und meine Funktion definiert ist (außerhalb des Konstruktor) wie folgt:

function methodName() 
     { 
//functioncode here 
     }

In meiner HTML-Datei ist der JavaScript-Code wie folgt:

<script type="text/javascript"> 
function callExternalInterface() { 
    thisMovie("swf").methodName(); 
} 
function thisMovie(movieName) { 
    if (navigator.appName.indexOf("Microsoft") != -1) { 
     return window[movieName] 
    } 
    else { 
     return document[movieName] 
    } 
} 
    </script>

Code für die Schaltfläche aufrufen die obige Funktion:

<input type="button" onclick="callExternalInterface()" value="Call ExternalInterface" />

Das Flash-Objekt ist die folgende Art und Weise eingebettet:

<object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0" width="655" height="324" align="middle" id="swf" name="swf"> 
    <param name="allowScriptAccess" value="always"> 
    <param name="allowFullScreen" value="false"> 
    <param name="movie" value="flash1.swf"> 
    <param name="menu" value="false"> 
    <param name="quality" value="best"> 
    <param name="bgcolor" value="#f3f3f3"> 
    <embed src="flash1.swf" menu="false" quality="best" bgcolor="#f3f3f3" width="655" height="324" align="middle" allowScriptAccess="always" allowFullScreen="false" type="application/x-shockwave-flash" pluginspage="http://www.adobe.com/go/getflashplayer" id="swf" name="swf"> 
    </object>

Nach der Firebug-Konsole, wenn ich auf den Button klicken, erhalte ich folgende Fehlermeldung:

thisMovie("swf").methodName is not a function

Es sieht aus wie es ist ein Javascript-Fehler, der die Funktion nicht erkennt. Ich habe den Großteil des Codes von dieser Seite erhalten, ich würde jede Hilfe schätzen. Vielen Dank!

Quelle

2012-04-07 Katherine Perotta

wo ist der Code für die JavaScript-Funktion callExternalInterface()? –

oops, sorry, war eine schlechte Paste von Code. fügte es dort hinzu. –

hast du verschiedene Browser ausprobiert? – K2xL

-1

Die Frage Problembeschreibung, die Sie unvollständig zur Verfügung gestellt haben, um zu irgendeinem Schluss zu kommen, warum Sie sich dem Problem gegenübersehen.

hier ein Arbeitstestcode, die ich geschaffen - den Teil des Codes, die Sie zur Verfügung gestellt haben -

JavaScript-Funktion in Header-Tag von HTML

<script type="text/javascript"> 
     function callExternalInterface() { 
     thisMovie("swf").methodName(); 
     } 

     function thisMovie(movieName) { 
     if(navigator.appName.indexOf("Microsoft") != -1) { 
      return window[movieName] 
     } else { 
      return document[movieName] 
     } 
     } 
</script>

Flash-Objekt eingebettet in folgenden Weise:

<body bgcolor="#ffffff" leftmargin="0" topmargin="0" marginwidth="0" marginheight="0"> 
     <object classid="clsid:d27cdb6e-ae6d-11cf-96b8-444553540000" codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=9,0,0,0" id="swf" width="550" height="400" align="middle"> 
      <param name="allowScriptAccess" value="Always" /> 
      <param name="movie" value="AS3-JS.swf" /> 
      <param name="quality" value="high" /> 
      <param name="bgcolor" value="#ffffff" /> 
      <embed src="AS3-JS.swf" quality="high" bgcolor="#ffffff" width="550" height="400" swLiveConnect=true id="swf" name="swf" align="middle" allowScriptAccess="Always" type="application/x-shockwave-flash" pluginspage="http://www.macromedia.com/go/getflashplayer" />

als Klasse-Datei

package { 

import flash.display.MovieClip; 
import flash.external.ExternalInterface; 

public class Main extends MovieClip { 


    public function Main() 
    { 
     // constructor code 
     ExternalInterface.addCallback("methodName",methodName); 
    } 

    private function methodName():void 
    { 
     msg_txt.htmlText = "Called" 
    } 
}

}

Quelle

2012-05-14 12:48:38 Kritavarman

hat überhaupt nicht funktioniert ... das Lesen der Eigenschaft methodName von undefined ist nicht möglich –

prüfen eine laufende Probe hier http://www.redcodelabs.com/2012/04/calling-actionscript-method-from-javascript/

Hier ist ein Code aus dem Post

package { 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.external.ExternalInterface; 
    import flash.text.TextField; 
    import flash.utils.Timer; 
    import flash.text.TextFieldType; 
    import flash.text.TextFieldAutoSize; 

    public class ExternalInterfaceExample extends Sprite { 
     private var input:TextField; 
     private var output:TextField; 
     private var sendBtn:Sprite; 

     public function ExternalInterfaceExample() { 
      input = new TextField(); 
      input.type = TextFieldType.INPUT; 
      input.background = true; 
      input.border = true; 
      input.width = 350; 
      input.height = 18; 
      addChild(input); 

      sendBtn = new Sprite(); 
      sendBtn.mouseEnabled = true; 
      sendBtn.x = input.width + 10; 
      sendBtn.graphics.beginFill(0xCCCCCC); 
      sendBtn.graphics.drawRoundRect(0, 0, 80, 18, 10, 10); 
      sendBtn.graphics.endFill(); 
      sendBtn.addEventListener(MouseEvent.CLICK, clickHandler); 
      addChild(sendBtn); 

      output = new TextField(); 
      output.y = 25; 
      output.width = 450; 
      output.height = 325; 
      output.multiline = true; 
      output.wordWrap = true; 
      output.border = true; 
      output.text = "Initializing...\n"; 
      addChild(output); 

      if (ExternalInterface.available) { 
       try { 
        output.appendText("Adding callback...\n"); 
        ExternalInterface.addCallback("sendToActionScript", receivedFromJavaScript); 
        if (checkJavaScriptReady()) { 
         output.appendText("JavaScript is ready.\n"); 
        } else { 
         output.appendText("JavaScript is not ready, creating timer.\n"); 
         var readyTimer:Timer = new Timer(100, 0); 
         readyTimer.addEventListener(TimerEvent.TIMER, timerHandler); 
         readyTimer.start(); 
        } 
       } catch (error:SecurityError) { 
        output.appendText("A SecurityError occurred: " + error.message + "\n"); 
       } catch (error:Error) { 
        output.appendText("An Error occurred: " + error.message + "\n"); 
       } 
      } else { 
       output.appendText("External interface is not available for this container."); 
      } 
     } 
     private function receivedFromJavaScript(value:String):void { 
      output.appendText("JavaScript says: " + value + "\n"); 
     } 
     private function checkJavaScriptReady():Boolean { 
      var isReady:Boolean = ExternalInterface.call("isReady"); 
      return isReady; 
     } 
     private function timerHandler(event:TimerEvent):void { 
      output.appendText("Checking JavaScript status...\n"); 
      var isReady:Boolean = checkJavaScriptReady(); 
      if (isReady) { 
       output.appendText("JavaScript is ready.\n"); 
       Timer(event.target).stop(); 
      } 
     } 
     private function clickHandler(event:MouseEvent):void { 
      if (ExternalInterface.available) { 
       ExternalInterface.call("sendToJavaScript", input.text); 
      } 
     } 
    } 
}

und die html/JS

<html lang="en"> 
<head> 
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" /> 
<title>ExternalInterfaceExample</title> 
<script language="JavaScript"> 
    var jsReady = false; 
    function isReady() { 
     return jsReady; 
    } 
    function pageInit() { 
     jsReady = true; 
     document.forms["form1"].output.value += "\n" + "JavaScript is ready.\n"; 
    } 
    function thisMovie(movieName) { 
     if (navigator.appName.indexOf("Microsoft") != -1) { 
      return window[movieName]; 
     } else { 
      return document[movieName]; 
     } 
    } 
    function sendToActionScript(value) { 
     thisMovie("ExternalInterfaceExample").sendToActionScript(value); 
    } 
    function sendToJavaScript(value) { 
     document.forms["form1"].output.value += "ActionScript says: " + value + "\n"; 
    } 
</script> 
</head> 
<body onload="pageInit();"> 

    <object classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000" 
      id="ExternalInterfaceExample" width="500" height="375" 
      codebase="http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab"> 
     <param name="movie" value="ExternalInterfaceExample.swf" /> 
     <param name="quality" value="high" /> 
     <param name="bgcolor" value="#869ca7" /> 
     <param name="allowScriptAccess" value="sameDomain" /> 
     <embed src="ExternalInterfaceExample.swf" quality="high" bgcolor="#869ca7" 
      width="500" height="375" name="ExternalInterfaceExample" align="middle" 
      play="true" loop="false" quality="high" allowScriptAccess="sameDomain" 
      type="application/x-shockwave-flash" 
      pluginspage="http://www.macromedia.com/go/getflashplayer"> 
     </embed> 
    </object> 

    <form name="form1" onsubmit="return false;"> 
     <input type="text" name="input" value="" /> 
     <input type="button" value="Send" onclick="sendToActionScript(this.form.input.value);" /><br /> 
     <textarea cols="60" rows="20" name="output" readonly="true">Initializing...</textarea> 
    </form> 

</body> 
</html>

Quelle

2012-05-14 14:30:37

Antwort

Verwandte Themen