Hier, eine modifizierte Version dieses Codes sollte den Trick tun. Schauen Sie sich das Buch natürlich auch an, es ist eine ausgezeichnete Schreibtisch-Ressource, auf die ich mich oft beziehe.
' This VBScript code prints the nested membership of a group.
' ---------------------------------------------------------------
' From the book "Active Directory Cookbook" by Robbie Allen
' ISBN: 0-596-00466-4
' ---------------------------------------------------------------
' ------ SCRIPT CONFIGURATION ------
strGroupDN = "<GroupDN>" ' e.g. cn=SalesGroup,ou=Groups,dc=rallencorp,dc=com
' ------ END CONFIGURATION ---------
strSpaces = " "
set dicSeenGroupMember = CreateObject("Scripting.Dictionary")
Wscript.Echo "Members of " & strGroupDN & ":"
DisplayMembers "LDAP://" & strGroupDN, strSpaces, dicSeenGroupMember
Function DisplayMembers (strGroupADsPath, strSpaces, dicSeenGroupMember)
set objGroup = GetObject(strGroupADsPath)
for each objMember In objGroup.Members
Wscript.Echo strSpaces & objMember.Name
if objMember.Class = "group" then
if dicSeenGroupMember.Exists(objMember.ADsPath) then
Wscript.Echo strSpaces & " ^already seen group member " & _
"(stopping to avoid loop)"
else
dicSeenGroupMember.Add objMember.ADsPath, 1
DisplayMembers objMember.ADsPath, strSpaces & " ", _
dicSeenGroupMember
end if
end if
next
End Function
Was meinen Sie mit "List down"? Möchten Sie eine Liste verschachtelter Gruppen für jede Gruppe in einer Weise erstellen, die nicht bricht, wenn ein Zirkelverweis existiert ODER Sie suchen einfach nach Gruppen, die an einer Kreisschleife beteiligt sind? – AnthonyWJones
Ich möchte nach verschachtelten kreisförmigen Gruppen suchen und auflisten, wie sie verschachtelt sind. –
Überprüfen Sie dies: http://www.rlmueller.net/CircularNested.htm – Adeel