Wie erhält man Elemente in Delphi Chromium Embedded?

Question

Um einen bestimmten DOM-Knoten aus einer TChromium-Instanz in das aktuelle Webdokument einzubetten, verwenden Sie unter Verwendung seiner ID ICefDomDocument.getElementById(). Aber wie finden Sie Elemente durch das Attribut NAME? Javascript hat die document.getElementsByName() -Methode und TWebBrowser (die IE umschließt) hat einen ähnlichen Anruf, aber ich kann nicht herausfinden, wie man das mit TChromium macht. Ich muss einige DOM-Elemente finden, die NAME-Attribute aber keine ID-Attribute haben. Ich suchte die ceflib Einheit und sah nichts, was es tun würde.

Seitliche Frage. Wenn jemand einen Link zu einer TChromium "Rezeptstil" -Seite oder einem Dokument hat, könnte ich es verwenden.

UPDATE: Während ich auf eine Antwort wartete, habe ich den folgenden Code für getElementsbyName() gefunden. Ich hätte gerne etwas schneller, als den gesamten DOM-Baum zu scannen. Wenn Sie etwas falsch im Code sehen lassen Sie mich wissen:

type 
    TDynamicCefDomNodeArray = array of ICefDomNode; 


// Given a Chromium document interface reference and a NAME attribute to search for, 
// return an array of all DOM nodes whose NAME attribute matches the desired. 
function getElementsByName(ADocument: ICefDomDocument; theName: string): TDynamicCefDomNodeArray; 

    // Get all the elements with a particular NAME attribute value and return 
    // an array of them. 
    procedure getElementsByName1(intfParentNode: ICefDomNode; theName: string; var aryResults: TDynamicCefDomNodeArray); 
    var 
     oldLen: integer; 
     intfChildNode: ICefDomNode; 
     theNameAttr: string; 
    begin 
     Result := nil; 
     intfChildNode := nil; 

     if Assigned(intfParentNode) then 
     begin 
      // Attributes are case insensitive. 
      theNameAttr := intfParentNode.GetElementAttribute('name'); 

      if AnsiSameText(theNameAttr, theName) then 
      begin 
       // Name attribute match. Add it to the results array. 
       oldLen := Length(aryResults); 
       SetLength(aryResults, oldLen + 1); 
       aryResults[oldLen] := intfParentNode; 
      end; // if AnsiSameText(intfParentNode.Name, theName) then 

      // Does the parent node have children? 
      if intfParentNode.HasChildren then 
      begin 
       intfChildNode := intfParentNode.FirstChild; 

       // Scan them. 
       while Assigned(intfChildNode) do 
       begin 
        getElementsByName1(intfChildNode, theName, aryResults); 

        if Assigned(intfChildNode) then 
         intfChildNode := intfChildNode.NextSibling; 
       end; 
      end; // if intfParentNode.HasChildren then 
     end; // if Assigned(intfParentNode) then 
    end; 

    // --------------------------------------------------------------- 

var 
    intfCefDomNode: ICefDomNode; 
begin 
    intfCefDomNode := nil; 
    Result := nil; 

    if Assigned(ADocument) then 
    begin 
     // Check the header. 
     intfCefDomNode := ADocument.Document; 

     if Assigned(intfCefDomNode) then 
     begin 
      // Check the parent. 
      getElementsByName1(intfCefDomNode, theName, Result); 
     end; // if Assigned(intfCefDomNode) then 
    end; // if Assigned(ADocoument) then 
end; 

// --------------------------------------------------------------- 

Answer 1

Es gibt keine Funktion wie von JavaScript ist getElementsByName oder getElementsByName im Chromium Embedded gebaut MSHTML noch ihre Delphi-Wrapper zu diesem Zeitpunkt. Sie können dies nur lösen, indem Sie über alle DOM-Elemente, z. Erstellen Sie Ihre eigene DOM-Besucherklasse wie folgt:

Bitte beachten Sie, die VisitDom Prozedur ist asynchron, so dass es sofort zurückkehrt (tatsächlich bevor der DOM-Besucher seine visit beendet) und es mit einer Momentaufnahme des DOM zum Zeitpunkt der Ausführung funktioniert .

type 
    TElementNameVisitor = class(TCefDomVisitorOwn) 
    private 
    FName: string; 
    protected 
    procedure visit(const document: ICefDomDocument); override; 
    public 
    constructor Create(const AName: string); reintroduce; 
    end; 

procedure ProcessElementsByName(const AFrame: ICefFrame; const AName: string); 
var 
    Visitor: TElementNameVisitor; 
begin 
    if Assigned(AFrame) then 
    begin 
    Visitor := TElementNameVisitor.Create(AName); 
    AFrame.VisitDom(Visitor); 
    end; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    ProcessElementsByName(Chromium1.Browser.MainFrame, 'NameAttributeValue'); 
end; 

{ TDOMElementNameVisitor } 

constructor TElementNameVisitor.Create(const AName: string); 
begin 
    inherited Create; 
    FName := AName; 
end; 

procedure TElementNameVisitor.visit(const document: ICefDomDocument); 

    procedure ProcessNode(ANode: ICefDomNode); 
    var 
    Node: ICefDomNode; 
    begin 
    if Assigned(ANode) then 
    begin 
     Node := ANode.FirstChild; 
     while Assigned(Node) do 
     begin 
     if Node.GetElementAttribute('name') = FName then 
     begin 
      // do what you need with the Node here 
      ShowMessage(Node.GetElementAttribute('value')); 
     end; 
     ProcessNode(Node); 
     Node := Node.NextSibling; 
     end; 
    end; 
    end; 

begin 
    ProcessNode(document.Body); 
end;