mehrere Dateien anhängen, um E-Mails oder das gesamte Verzeichnis (VBA) zu senden

Question

Ich versuche, eine E-Mail mit mehreren Anhängen über VBA und Outlook zu senden.

Der Code Ich arbeite, wenn ich den Pfad zu einem Anhang/Datei angeben, und ich kann auch mehrere Anhänge hinzufügen, wenn ich genau weiß, was sie sind, aber ich werde nicht vorwärts gehen - es wird verschiedene Zählungen sowie Dateinamen geben .

Ich würde gerne mit einem Platzhalter senden, wie in meinem Beispiel unten gezeigt, aber ich denke, ich muss eine Art Schleife verwenden, die auf ein Verzeichnis zeigt.

Ich habe eine Tonne nach einer Lösung gesucht, aber ich habe noch nichts gesehen, das mit meiner spezifischen Situation funktioniert.

 Private Sub Command22_Click() 
     Dim mess_body As String 
     Dim appOutLook As Outlook.Application 
     Dim MailOutLook As Outlook.MailItem 
     Set appOutLook = CreateObject("Outlook.Application") 
     Set MailOutLook = appOutLook.CreateItem(olMailItem) 

      Set appOutLook = CreateObject("Outlook.Application") 
      Set MailOutLook = appOutLook.CreateItem(olMailItem) 
      With MailOutLook 
      .BodyFormat = olFormatRichText 
      .To = "test@test.org" 
      .Subject = "test" 
      .HTMLBody = "test" 
      .Attachments.Add ("H:\test\Adj*.pdf") 
      '.DeleteAfterSubmit = True 
      .Send 
      End With 
      MsgBox "Reports have been sent", vbOKOnly 
     End Sub 

Answer 1

Ist das, was Sie versuchen? (Ungetestet)

Private Sub Command22_Click() 
    Dim mess_body As String, StrFile As String, StrPath As String 
    Dim appOutLook As Outlook.Application 
    Dim MailOutLook As Outlook.MailItem 

    Set appOutLook = CreateObject("Outlook.Application") 
    Set MailOutLook = appOutLook.CreateItem(olMailItem) 

    '~~> Change path here 
    StrPath = "H:\test\" 

    With MailOutLook 
     .BodyFormat = olFormatRichText 
     .To = "test@test.org" 
     .Subject = "test" 
     .HTMLBody = "test" 

     '~~> *.* for all files 
     StrFile = Dir(StrPath & "*.*") 

     Do While Len(StrFile) > 0 
      .Attachments.Add StrPath & StrFile 
      StrFile = Dir 
     Loop 

     '.DeleteAfterSubmit = True 
     .Send 
    End With 

    MsgBox "Reports have been sent", vbOKOnly 
End Sub