Suchen Sie nach einem Wort und kopieren Sie die Zelle neben es in eine andere Excel-Arbeitsmappe mit VBA

Question

Ich bin derzeit auf der Suche nach "Quote ID:" in der Spalte A von workbook1, dann kopieren Sie die Zelle, die neben ihr in der Spalte ist B, und fügen Sie dann diese Zelle in Arbeitsmappe2 in Zelle B67 ein.

Irgendwelche Ideen? Ich fand etwas Kodierung, die ähnlich ist, was ich brauche, aber sie waren alle komplexer, als ich es brauchte, und sie kopierten die ganze Reihe anstatt die angrenzende Zelle.

Answer 1

Beginnen Sie hier:

Sub SingleCell() 
    Dim r1 As Range, r2 As Range 

    Set r1 = Workbooks("Book1").Sheets("Sheet1").Range("A:A").Find(What:="Quote ID:").Offset(0, 1) 
    Set r2 = Workbooks("Book2").Sheets("Sheet1").Range("B67") 
    r1.Copy r2 
End Sub 

Answer 2

Das ist nicht zu schwer sein sollte. Sie müssen jedoch die Namen der Arbeitsmappe und des Arbeitsblatts ausfüllen, damit sie ordnungsgemäß funktioniert.

Sub searchMacro() 

Dim wb1 As Workbook, wb2 As Workbook, ws1 As Worksheet, ws2 As Worksheet 
Dim srch As String 
Dim col As Range, pstCell As Range, sRng As Range 

'Identify workbooks 
Set wb1 = Workbooks("workbook to search IDs Name") 
Set wb2 = Workbooks("workbook to paste cell name") 

'Identify worksheets 
Set ws1 = wb1.Sheets("Sheet to search IDs Name") 
Set ws2 = wb2.Sheets("Sheet to paste cell name") 

'Input which Quote to search for. This is a pop-up windows for the user to input the value into 
srch = InputBox("Input Quote ID:", "Search ID") 

'Search Column 
Set col = ws1.Columns("A") 

'Paste Cell 
Set pstCell = ws2.Range("B67") 

'Search the column for the ID 
Set sRng = col.Find(srch) 

If Not sRng Is Nothing Then 
    'Quote ID was found 
    sRng.Offset(0, 1).Copy pstCell 
Else 
    'Quote ID was not found 
    MsgBox "Quote ID " & srch & " was not found", vbCritical, "Not found" 
End If 

End Sub 

Ich hoffe, dass für Sie arbeitet