100 meist verwendete Zeichenfolgen in Datei

Question

Wie kann ich die 100 meistverwendeten Zeichenfolgen (Wörter) in einer .txt Datei mit Perl finden? Bisher habe ich folgendes:

use 5.012; 
use warnings; 

open(my $file, "<", "file.txt"); 

my %word_count; 
while (my $line = <$file>) { 
    foreach my $word (split ' ', $line) { 
    $word_count{$word}++; 
    } 
} 

for my $word (sort keys %word_count) { 
    print "'$word': $word_count{$word}\n"; 
} 

Aber das zählt nur jedes Wort und organisiert es in alphabetischer Reihenfolge. Ich möchte die Top 100 am häufigsten verwendeten Wörter in der Datei, sortiert nach Anzahl der Vorkommen. Irgendwelche Ideen?

Verwandte: Count number of times string repeated in files perl

Answer 1

von den feinen perlfaq4 Lesen (1) manpage, ein how to sort hashes by value lernt. Versuchen Sie es also. Es ist eher idiomatisch "perlian" als Ihr Ansatz.

#!/usr/bin/env perl  
use v5.12; 
use strict; 
use warnings; 
use warnings FATAL => "utf8"; 
use open qw(:utf8 :std); 

my %seen; 
while (<>) { 
    $seen{$_}++ for split /\W+/; # or just split; 
} 

my $count = 0; 
for (sort { 
     $seen{$b} <=> $seen{$a} 
        || 
      lc($a) cmp lc($b) # XXX: should be v5.16's fc() instead 
        || 
       $a cmp $b 
    } keys %seen) 
{ 
    next unless /\w/; 
    printf "%-20s %5d\n", $_, $seen{$_}; 
    last if ++$count > 100; 
} 

Wenn gegen sich selbst führen, die ersten 10 Zeilen der Ausgabe sind:

seen      6 
use      5 
_      3 
a      3 
b      3 
cmp      2 
count     2 
for      2 
lc      2 
my      2