Lösen von gegenseitig rekursiven Bedingungen in Prolog

Question

Ich versuche einige wechselseitig rekursive Bedingungen mit SWI-Prolog zu lösen. Diese Einschränkungen sind relativ einfach, aber die Abfrage jeder dieser Prädikate führt zu unendlicher Rekursion:

%If X is an animal, then X is a bird or a mammal, and vice-versa. 
animal(X) :- 
    (mammal(X);bird(X)), 
    (male(X);female(X)). 

male(X) :- animal(X). 
female(X) :- animal(X). 

bird(X) :- (X='parrot';X='pigeon'),animal(X). 

mammal(X) :- (X='cat';X='dog'),animal(X). 

Wäre es möglich, diese Einschränkungen in Prolog zu lösen, ohne sie zu nicht-rekursive zu machen?

Ich schrieb ein ähnliches Programm mit mehreren Basis Fällen, aber die Abfrage mammal(X),bird(X) führt immer noch zu unendliche Rekursion statt false der Rückkehr:

%If X is an animal, then X is a bird or a mammal, and vice-versa. 
animal(X) :- 
    (mammal(X);bird(X)). 

bird('parrot'). 
bird('pigeon'). 
bird(X) :- (X='parrot';X='pigeon'),animal(X). 

mammal('cat'). 
mammal('dog'). 
mammal(X) :- (X='cat';X='dog'),animal(X). 

Answer 1

Mit constraint handling rules können Lösungen für wechselseitig rekursive Bedingungen gefunden werden.

Dies ist ein Satz von sich gegenseitig rekursive Einschränkungen:

%If X is an animal, then X is a bird or a mammal, and vice-versa. 
:- use_module(library(chr)). 

:- chr_constraint mammal/2,bird/2,animal/1,male/1,female/1,species/2. 

animal(X) <=> 
    (mammal(X,Species);bird(X,Species)), 
    (male(X);female(X)). 

male(X),female(X) ==> false. 

bird(X,Species) <=> member(Species,[parrot,pigeon,crow]),species(X,Species). 
bird(X,Species) ==> animal(X). 

mammal(X,Species) <=> member(Species,[cat,dog,bull]),species(X,Species). 
mammal(X,Species) ==> animal(X). 

species(X,bull) ==> male(X). 

... und dies ist die Ausgabe einer Abfrage für dieses Programm:

?- male(X),mammal(X,Species). 
male(_G67406) 
species(_G67406,cat) 
Species = cat 

Answer 2

eine rekursive Constraint Solving erfordert eine oder mehrere Basis Fällen; Sie haben keine zur Verfügung gestellt. Das Problem ist nicht mit Prolog; es ist mit der Problemdefinition.

Answer 3

Ich denke, was Sie versuchen zu bekommen ist, dass Sie Vögel haben und Sie Säugetiere haben. Und du versuchst weiter zu beweisen, dass eine Kreatur ein Tier ist, wenn es entweder ein Vogel oder ein Säugetier ist.

Der Code ist derzeit überbestimmt und hat eine zirkuläre Logik.

durch den Code Wandern ...

animal(X) :- 
    (mammal(X); bird(X)). 

Diese besagt, dass X ist ein animalwennX ist ein mammal oder X ist ein bird. So weit, ist es gut.

Die Beschreibung bird lautet:

bird('parrot'). 
bird('pigeon'). 

Diese Tatsachen sind, die angeben, dass ein parrot ein bird ist und ein pigeon ist ein bird. Aber dann gibt es diese Regel:

bird(X) :- (X='parrot';X='pigeon'),animal(X). 

die besagt, dass X ist ein birdwennX ist entweder ein parrot oder pigeon, und wenn X ist ein animal. Aus den beiden vorherigen Tatsachen geht bereits hervor, dass es sich bei parrot und pigeon um Vögel handelt. Warum ist diese Regel notwendig? Und es fügt des Weiteren die Bedingung hinzu, dass X eine animal ist, die ihrerseits in Bezug auf bird und mammal definiert ist, also kreisförmig ist.

Ähnliches gilt für die mammal Definition.Es hat die erforderlichen Tatsachen für Säugetiere:

mammal('cat'). 
mammal('dog'). 

Und dann overspecifies mit zirkulärer Logik:

mammal(X) :- (X='cat';X='dog'), animal(X). 

Die Essenz das, was Sie brauchen, ist einfach:

bird('parrot'). 
bird('pigeon'). 

mammal('cat'). 
mammal('dog'). 

animal(X) :- 
    mammal(X); bird(X). 

Diese Logik definiert Welche Kreaturen sind Vögel oder Säugetiere, die Fakten verwenden, dann gibt es eine Regel, die besagt, dass, wenn eine Kreatur bekannt ist, ein Vogel oder ein Säugetier zu sein, dann ist es ein Tier.

Answer 4

Eine Lösung für solche Probleme ist die einfache Aktivierung des Mechanismus Ihres Prolog-Systems.

Zum Beispiel in SWI-Prolog (neueste Entwickler-Version), wenn ich einfach die folgenden Anweisungen zu Beginn des Programms hinzu:

:- use_module(library(tabling)). 

:- table animal/1. 

Dann bekomme ich zum Beispiel:

 
?- animal(X). 
false. 

?- male(X). 
false. 

?- bird(X). 
false. 

Also, in diesen Fällen finden wir immer noch keine Lösung, aber zumindest bekommen wir Antworten.