Historische Zeitstempel von UTC in Lokal umwandeln

Question

Ich habe eine Datei mit Zeitstempeln, die in der Vergangenheit liegen und alle in UTC sind. Ich muss diese in Eastern Time konvertieren. Ich bin nah dran, aber es dreht sich um die Umstellung der Sommerzeit.

#!/usr/bin/perl 
use strict; 
use warnings; 
use Time::Piece; 

#DST not in effect 
my $utc = '2015-03-08 01:59:00.000'; 
my $local = utc_to_local($utc); 
print "DST not in effect: utc($utc) = local($local)\n"; 

#DST not in effect 
$utc = '2015-03-08 02:00:00.000'; 
$local = utc_to_local($utc); 
print "DST not in effect: utc($utc) = local($local)\n"; 


sub utc_to_local 
{ 
    my $utc_ts = $_[0]; #this has ms on right side, we want left 19 characters 
    $utc_ts = substr $utc_ts, 0, 19; 
    my $local_tp = localtime->strptime($utc_ts, '%Y-%m-%d %H:%M:%S'); 
    $local_tp = $local_tp + $local_tp->tzoffset(); 

    return $local_tp->strftime('%Y-%m-%d %H:%M:%S'); 
} 

Wie Sie sehen können, wenn ich 1.59 UTC anprobieren 08.03 und 02.00 UTC auf 3/8, denkt, dass es die Änderung stattgefunden hat, aber 02.00 UTC ist nur 3/7 an 9 Uhr. Abgesehen von der Umstellung auf die Umstellung auf Sommerzeit werden die Einstellungen -5 und -4 korrekt korrigiert.

DST not in effect: utc(2015-03-08 01:59:00.000) = local(2015-03-07 20:59:00) 
DST not in effect: utc(2015-03-08 02:00:00.000) = local(2015-03-07 22:00:00) 

Answer 1

$utc_ts ist keine Ortszeit.

my $local_tp = localtime->strptime($utc_ts, '%Y-%m-%d %H:%M:%S'); 

sollte

sein

my $utc_tp = Time::Piece->strptime($utc_ts, '%Y-%m-%d %H:%M:%S'); 

---

Dann gibt es noch das Problem auf lokale Zeit umzuwandeln.

$local_tp = $local_tp + $local_tp->tzoffset(); 

sollte

my $local_tp = localtime($utc_tp->epoch); 

---

Alle zusammen sein:

#!/usr/bin/perl 
use strict; 
use warnings; 
use POSIX qw(); 
use Time::Piece; 

sub utc_to_local { 
    my ($utc_ts) = @_; 
    my $utc_tp = Time::Piece->strptime($utc_ts, '%Y-%m-%d %H:%M:%S'); 
    my $local_tp = localtime($utc_tp->epoch); 
    return $local_tp->strftime('%Y-%m-%d %H:%M:%S'); 
} 

sub local_to_utc { 
    my ($local_ts) = @_; 
    my $local_tp = Time::Piece->strptime($local_ts, '%Y-%m-%d %H:%M:%S'); 
    my $utc_tp = gmtime($local_tp->epoch); 
    return $utc_tp->strftime('%Y-%m-%d %H:%M:%S'); 
} 

{ 
    $ENV{TZ} = 'America/Toronto'; 
    POSIX::tzset(); 

    # DST not in effect 
    my $utc = '2015-03-08 06:59:00.000'; 
    my $local = utc_to_local(substr($utc, 0, -4)); 
    print "DST not in effect: utc($utc) = local($local)\n"; 

    # DST not in effect 
    $utc = '2015-03-08 07:00:00.000'; 
    $local = utc_to_local(substr($utc, 0, -4)); 
    print "DST not in effect: utc($utc) = local($local)\n"; 
} 

Ausgang:

DST not in effect: utc(2015-03-08 06:59:00.000) = local(2015-03-08 01:59:00) 
DST not in effect: utc(2015-03-08 07:00:00.000) = local(2015-03-08 03:00:00)