Batch-Datei, um zu prüfen, ob Dateien in einem Verzeichnis existieren, die nicht in einer Dateiliste existieren

Question

Ich habe eine Batch-Datei, die meine Ordner gegen eine Dateiliste recursiert und grundsätzlich zwei Berichte erstellt. Eine wenn eine Datei existiert und eine wenn eine Datei nicht existiert. Was ich jetzt tun möchte, ist herauszufinden, ob eine Datei in den Verzeichnissen existiert, aber nicht in der Dateiliste existiert (d. H. Ich habe extra Dateien).

Hier ist meine aktuelle Datei ..

FOR /F "usebackqdelims=" %%f IN ("filelist.txt") DO (IF EXIST "%%f" (ECHO %%f exists >> "%~dp0\Exists.txt") ELSE (ECHO %%f doesn't exist >> "%~dp0\doesntexist.txt")) 

Answer 1

Die Standard-Windows-Konsolenanwendung FINDSTR für diese Aufgabe ist auf jeden Fall eine sehr gute Wahl, da sie unten durch den Code zu sehen ist.

@echo off 
setlocal 
set "ListFiles=%~dp0FileList.txt" 
set "ListExist=%~dp0Exist.txt" 
set "ListMissing=%~dp0NotExist.txt" 
set "ListExtra=%~dp0Extra.txt" 
set "ListCurrent=%TEMP%\ListCurrent.tmp" 

rem Get list of all files in current directory and its subdirectories with 
rem full path into a temporary list file. If the current directory tree 
rem contains no file, delete empty list file and exit batch processing. 
dir /A-D /B /ON /S >"%ListCurrent%" 2>nul 

if errorlevel 1 (
    copy "%ListFiles%" "%ListMissing%" >nul 
    if exist "%ListExist%" del "%ListExist%" 
    if exist "%ListExtra%" del "%ListExtra%" 
    goto EndBatch 
) 

%SystemRoot%\System32\findstr.exe /I /L /X /G:"%ListFiles%" "%ListCurrent%" >"%ListExist%" 
%SystemRoot%\System32\findstr.exe /I /L /X /V /G:"%ListExist%" "%ListFiles%" >"%ListMissing%" 
%SystemRoot%\System32\findstr.exe /I /L /X /V /G:"%ListExist%" "%ListCurrent%" >"%ListExtra%" 

:EndBatch 
del "%ListCurrent%" 
endlocal 

Dieser Batch Code erfordert, dass FileList.txt im Verzeichnis der Batch-Datei der Dateinamen mit vollständigem Pfad enthält.

Hinweis:%~dp0 wird auf den Pfad der Stapeldatei erweitert, die bereits mit einem umgekehrten Schrägstrich endet. Geben Sie daher keinen zusätzlichen Backslash vor dem Dateinamen an.

Um die verwendeten Befehle und ihre Funktionsweise zu verstehen, öffnen Sie ein Eingabeaufforderungsfenster, führen Sie die folgenden Befehle aus und lesen Sie alle Hilfeseiten, die für jeden Befehl angezeigt werden, sorgfältig durch.

• copy /?
• del /?
• dir /?
• echo /?
• endlocal /?
• findstr /? ... wichtigsten zu verstehen, wie das Filtern der Listen arbeiten.
• goto /?
• if /?
• rem /?
• set /?
• setlocal /?

Siehe auch den Microsoft Artikel über Using command redirection operators für eine Erklärung der >, >nul und 2>nul.

Answer 2

@echo off 
setlocal 

rem Load the list of filenames in *the subscripts* of an array 
FOR /F "usebackq delims=" %%f IN ("filelist.txt") DO set "name["%%f"]=1" 

rem Process files, remove elements of existent files from array 
for %%f in (*.*) do (
    IF defined name["%%f"] (
     ECHO %%f exists >> "%~dp0Exists.txt" 
     set "name["%%f"]=" 
    ) ELSE (
     ECHO %%f is extra >> "%~dp0ExtraFiles.txt" 
    ) 
) 

rem Report remaining elements in the array 
for /F "tokens=2 delims=[]" %%f in ('set name[') do (
    ECHO %%~f doesn't exist >> "%~dp0doesntexist.txt" 
)