Wie schützt man eine gemeinsame Ressource mit Mutexen?

Question

Ich habe eine gemeinsame Ressource, die ich will 1 und nur 1 Instanz meiner Anwendung (oder es ist COM API) zu jeder Zeit Zugriff haben. Ich habe versucht, diese Ressource mit Mutexe zu schützen, aber wenn mehrere Threads einer Host-Dotnet-Anwendung versuchen, auf das COM-Objekt zuzugreifen, scheint der Mutex nicht freigegeben zu sein. Dies ist der Code, mit dem ich meine Ressource geschützt habe.

repeat 
    Mutex := CreateMutex(nil, True, PChar('Connections')); 
until (Mutex <> 0) and (GetLastError <> ERROR_ALREADY_EXISTS); 
    try 
    //use resource here! 
    finally 
    CloseHandle(Mutex); 
    end; 

Wenn ich die Threads gleichzeitig ausgeführt werden, der erste Thread gets durch (offensichtlich, wobei der erste den Mutex erstellen), aber nachfolgende Threads werden in der Wiederholungsschleife gefangen. Wenn ich jeden Thread in 5-Sekunden-Intervallen abspiele, dann ist alles in Ordnung.

Ich vermute, dass ich nicht Mutexe hier richtig verwende, aber ich habe sehr wenig Dokumentation darüber gefunden, wie dies zu tun ist.

Irgendwelche Ideen?

Answer 1

Sie verwenden den Mutex falsch. Du solltest darauf warten und es freigeben, es nicht ständig neu erstellen.

Während der Initialisierung:

Mutex := CreateMutex(nil, False, 'Connections'); 
if Mutex = 0 then 
    RaiseLastOSError; 

Wenn Sie die Ressource

if WaitForSingleObject(Mutex, INFINITE) <> WAIT_OBJECT_0 then 
    RaiseLastOSError; 
try 
    // Use resource here 
finally 
    ReleaseMutex(Mutex) 
end; 

Während der Finalisierung

CloseHandle(Mutex); 

auch zugreifen möchten, da mutexes global sind, sollten Sie etwas holen mehr einzigartig als "Verbindungen" für den Namen. Wir haben eine GUID am Ende von uns hinzugefügt.

Answer 2

Versuchen Sie mit diesem einfachen Demo-Code. Starten Sie mehrere Instanzen der Anwendung, und Sie können von der Hintergrundfarbe sehen, wie sie die Mutex teilen:

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    fMutex := SyncObjs.TMutex.Create(nil, False, 'GlobalUniqueName'); 
end; 

procedure TForm1.FormDestroy(Sender: TObject); 
begin 
    fMutex.Free; 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
begin 
    Color := clRed; 
    Update; 
    fMutex.Acquire; 
    try 
    Color := clGreen; 
    Update; 
    Sleep(5 * 1000); 
    finally 
    fMutex.Release; 
    end; 
    Color := clBtnFace; 
end; 

Bitte beachte, dass ich die TMutex Klasse von der SyncObjs Einheit zu verwenden, entschied sich, die Dinge vereinfacht.