aufrufen Delphi-Prozedur als Methode

Question

Hier ist mein einfacher Code, der gut kompiliert, aber Zugriffsverletzung erhöhen. Es tritt MD Prozedur und Debugger zeigt einige X und Y-Wert, aber nach dem Beenden der Prozedur AV passiert. Hoffe jemand kann helfen.

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Controls, Forms, ExtCtrls; 

type 
    TForm1 = class(TForm) 
    Panel1: TPanel; 
    procedure FormCreate(Sender: TObject); 
    end; 

var 
    Form1: TForm1; 

implementation 

    {$R *.dfm} 

procedure MD(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer); 
begin 
    form1.caption:= inttostr(x)+ ' '+ inttostr(y); 
end; 

procedure TForm1.FormCreate(Sender: TObject); 

function MakeMethod(data, code: pointer): TMethod; 
begin 
    result.Data:= data; 
    result.Code:= code; 
end; 

begin 
    panel1.OnMouseDown:= TMouseEvent(MakeMethod(nil, @MD)); 
end; 

end. 

Dank

Answer 1

Versuchen MD macht ein Mitglied Ihrer Formularklasse. Bearbeiten Sie Ihr Beispiel die folgende Art und Weise: In der Klassendefinition:

type 
TForm1 = class(TForm) 
    Panel1: TPanel; 
    procedure FormCreate(Sender: TObject); 
    procedure MD(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer); 
end; 

später im Code sicherstellen, dass der Besitzer des MD-Methode zur Eingabe wie folgt:

procedure TForm1.MD(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer); 

Schließlich, wenn die Zuordnung dieses Eventhandler Ihre Komponente, alles, was Sie tun müssen, ist:

panel1.OnMouseDown:= MD; 

ich weiß nicht, was Ihre Absicht war, aber das ist, wie Sie kümmern sich um Eventhandler zur Laufzeit übernehmen.

Answer 2

MD Signatur sollte zusätzliche versteckte Parameter enthalten; Es löst AV-Problem.

unit Unit1; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, ExtCtrls; 


type 
    TForm1 = class(TForm) 
    Panel1: TPanel; 
    procedure FormCreate(Sender: TObject); 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure MD(Instance, Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer); 
begin 
    form1.caption:= inttostr(x)+ ' '+ inttostr(y); 
end; 

procedure TForm1.FormCreate(Sender: TObject); 

function MakeMethod(data, code: pointer): TMethod; 
begin 
    result.Data:= data; 
    result.Code:= code; 
end; 

begin 
    panel1.OnMouseDown:= TMouseEvent(MakeMethod(nil, @MD)); 
end; 

end.