Laufzeitfehler 424: Objekt erforderlich mit FileDialog.SourceDataFile & fdgOpen.SelectedItems (1)

Question

Ich möchte den Benutzer auffordern, die Rohdatendatei auszuwählen, und Abbrechen, wenn sie im Feld FileDialog auf "Abbrechen" klicken.

Aber ich bin immer die Debug-Option und die Fehlermeldung "Runtime 424 Fehler Objekt erforderlich" auf der Linie:

FileDialog.SourceDataFile = fdgOpen.SelectedItems (1)

wie ich bin ganz neu Die ganze Open-a-File-wie-diese Methode, jede Hilfe wird geschätzt werden!

Sub Open file 
    Dim fldr As FileDialog 

    Dim Answer As Integer 
    Dim fdgOpen As FileDialog 
    sPath = Environ("USERPROFILE") & "\Skrivebord\" 
    Set fdgOpen = Application.FileDialog(msoFileDialogOpen) 


    Answer = MsgBox("Continue? ", vbYesNo + vbQuestion, "Update") 
     If Answer = vbNo Then GoTo Nej Else 
       Application.ScreenUpdating = False 
       Application.Calculation = xlCalculationManual 


       fdgOpen.Title = "FileDialogTitle" 
       fdgOpen.InitialFileName = "Select raw data" 
       fdgOpen.Show 

        If fdgOpen.SelectedItems.Count <= 0 Then GoTo Nej Else 
        FileDialog.SourceDataFile = fdgOpen.SelectedItems(1) 

    Nej: MsgBox ("You cancelled") 

End sub 

Answer 1

Sie erhalten den Object Required Fehler, da der Code nicht versteht, was FileDialog ist in FileDialog.SourceDataFile = fdgOpen.SelectedItems(1)

Hier ist eine viel einfachere Version ist, die die native Excel verwendet Application.GetOpenFilename

das ist, was du bist versuchen?

Sub Openfile() 
    Dim Ret, Ans 

    Ans = MsgBox("Continue? ", vbYesNo + vbQuestion, "Update") 

    If Ans = vbNo Then 
     MsgBox "You cancelled" 
    Else 
     Ret = Application.GetOpenFilename("Raw Data Files (*.*), *.*", , "Select Raw Data") 

     If Ret = False Then 
      MsgBox "You cancelled" 
     Else 
      Application.ScreenUpdating = False 
      Application.Calculation = xlCalculationManual 

      Workbooks.Open Ret 

      Application.ScreenUpdating = True 
      Application.Calculation = xlCalculationAutomatic 
     End If 
    End If 
End Sub 

EDIT

Dies ist, wie Sie o den FileDialog

Sub Openfile() 
    Dim dlgOpen As FileDialog 
    Dim Ans 
    Dim sPath As String 

    Ans = MsgBox("Continue? ", vbYesNo + vbQuestion, "Update") 

    sPath = Environ("USERPROFILE") & "\Skrivebord\" 

    If Ans = vbNo Then 
     MsgBox "You cancelled" 
    Else 
     Set dlgOpen = Application.FileDialog(_ 
     FileDialogType:=msoFileDialogOpen) 

     With dlgOpen 
      .Title = "Select Raw Data" 
      '~~> Add the folder path and file name 
      .InitialFileName = sPath & "Myfile.xlsx" 
      .Show 

      If .SelectedItems.Count > 0 Then 
       Application.ScreenUpdating = False 
       Application.Calculation = xlCalculationManual 

       Workbooks.Open .SelectedItems(1) 

       Application.ScreenUpdating = True 
       Application.Calculation = xlCalculationAutomatic 
      Else 
       MsgBox "You cancelled" 
      End If 
     End With 
    End If 
End Sub