Wie kann ich XML :: LibXML von Perl verwenden, um ein Attribut in einem Tag zu extrahieren?

Question

Ich habe eine XML-Datei

<PARENT > 
<TAG string1="asdf" string2="asdf" > 
</TAG > 
</PARENT> 

Ich möchte hier den Zeichenfolge2 Wert extrahieren .. und auch ich will es auf einen neuen Wert setzen ..

Wie das zu tun?

Answer 1

Verwenden von XPath-Ausdrücken

use strict;                              
use warnings;                              

use XML::LibXML;                             
use Data::Dumper;                             

my $doc = XML::LibXML->new->parse_string(q{                      
<PARENT>                               
    <TAG string1="asdf" string2="asdfd">                       
    </TAG>                              
</PARENT>                               
});                                

my $xpath = '/PARENT/TAG/@string2';                        
# getting value of attribute:                          
print Dumper $doc->findvalue($xpath);                        
my ($attr) = $doc->findnodes($xpath);                        

# setting new value:                            
$attr->setValue('dfdsa');                           
print Dumper $doc->findvalue($xpath);                        

# do following if you need to get string representation of your XML structure 
print Dumper $doc->toString(1);        

Und lesen Sie Dokumentation, natürlich :)

Answer 2

Sie XML verwenden könnte :: Parser als auch den Wert zu erhalten. Für weitere Informationen siehe zum XML::Parser documentation:

#!/usr/local/bin/perl 
use strict; 
use warnings; 


use XML::Parser; 
use Data::Dumper; 

my $attributes = {}; 

my $start_handler = sub 
{ 
    my ($expat, $elem, %attr) = @_; 
    if ($elem eq 'TAG') 
    { 
     $attributes->{$attr{'string1'}} = 'Found'; 
    } 
}; 


my $p1 = new XML::Parser(
     Handlers => { 
      Start => $start_handler 
     } 
); 

$p1->parsefile('test.xml'); 

print Dumper($attributes); 

Answer 3

Ich glaube, Sie könnten mit XML::Simple besser dran beginnen und spielen um ein wenig zuerst:

#!/usr/bin/perl 

use strict; 
use warnings; 

use XML::Simple; 

my $xml = XMLin(\*DATA); 

print $xml->{TAG}->{string2}, "\n"; 

$xml->{TAG}->{string2} = "asdf"; 

print XMLout($xml, RootName => 'PARENT'); 

__DATA__ 
<PARENT> 
<TAG string1="asdf" string2="value of string 2"> 
</TAG> 
</PARENT> 

Answer 4

Vielen Dank für Ihre Antworten. Ich fand eine andere Antwort in "Config file processing with LibXML2", die ich sehr nützlich fand.