Header in QML-Spalte

Question

Ich habe dieses Stück Code in QML, aber ich bin nicht in der Lage, einen statischen Text als Header jeder Spalte hinzuzufügen.

Ich habe versucht, online zu suchen, aber ich finde nicht den Asnwer. Oder ich verstehe es einfach nicht.

Component { 

    id: pedido   
    Item { 
     id: item 
     width: parent.width; 
     Row { 
      id: row 
      width: parent.width 
      anchors.verticalCenter: parent.verticalCenter 
       Column { 
         width: parent.width * 0.3      
         Text {       
          text: " " + codigo; 
          font.family: "Helvetica"                  
          font.pointSize: 14 
          font.bold: true 
          color: item.ListView.isCurrentItem ? "white" : "black"      } 
       Column {        
         width: parent.width * 0.5 
         Text {      
          text: "  " + nombre; 
          font.family: "Helvetica"                
          font.pointSize: 14 
          font.bold: true 
          color: item.ListView.isCurrentItem ? "white" : "black" 
          }  
         } 
       Column { 
         width: parent.width * 0.2       
         Text {      
          text: "  " + fecha; 
          font.family: "Helvetica"                
          font.pointSize: 14 
          font.bold: true   
    } 
}  

Sorgen Sie sich nicht, wenn es {} fehlen.

Answer 1

Sie sollten Ihre eigenen header implementieren. Weitere Informationen in der .

Lassen Sie mich Ihnen ein Beispiel mit einem einfachen ListModel & ListView:

import QtQuick 2.5 
import QtQuick.Window 2.2 

Window { 
    visible: true 
    width: 500 
    height: 500 

    Rectangle { 
     width: 300 
     height: 400 

     Component { 
      id: listDelegate 

      Item { 
       width: 400; 
       height: 50; 

       Row { 
        Column { 
         width: 100 
         Text { text: codigo } 
        } 
        Column { 
         width: 100 
         Text { text: nombre } 
        } 
        Column { 
         width: 100 
         Text { text: fecha } 
        } 
       } 
      } 
     } 

     ListModel { 
      id: listModel 

      ListElement { 
       codigo: "111" 
       nombre: "AAA" 
       fecha: "28/08/2001" 
      } 
      ListElement { 
       codigo: "222" 
       nombre: "BBB" 
       fecha: "28/08/2002" 
      } 
      ListElement { 
       codigo: "333" 
       nombre: "CCC" 
       fecha: "28/08/2003" 
      } 
     } 

     ListView { 
      id: listView 
      anchors.fill: parent 
      model: listModel 
      delegate: listDelegate 
      focus: true 
      header: myheader 
     } 
    } 

    Component {  //instantiated when header is processed 
     id: myheader 
     Rectangle { 
      gradient: mygradient 
      border {color: "#9EDDF2"; width: 2} 
      width: parent.width; height: 50 

      Row { 
       Column { 
        width: 100 
        Text { text: "Codigo" } 
       } 

       Column { 
        width: 100 
        Text { text: "Nombre" } 
       } 

       Column { 
        width: 100 
        Text { text: "Fecha" } 
       } 
      } 
     } 
    } 

    Gradient { 
     id: mygradient 
     GradientStop { position: 0.0; color: "#8EE2FE"} 
     GradientStop { position: 0.66; color: "#7ED2EE"} 
    } 
}