Wie kann ich alle Pivot-Tabellen in meiner Excel-Arbeitsmappe mit einem Makro aktualisieren?

Question

Ich habe eine Arbeitsmappe mit 20 verschiedenen Pivot-Tabellen. Gibt es eine einfache Möglichkeit, alle Pivot-Tabellen zu finden und sie in VBA zu aktualisieren?

Answer 1

Ja.

ThisWorkbook.RefreshAll 

Oder, wenn Ihre Excel-Version alt genug ist,

Dim Sheet as WorkSheet, Pivot as PivotTable 
For Each Sheet in ThisWorkbook.WorkSheets 
    For Each Pivot in Sheet.PivotTables 
     Pivot.RefreshTable 
     Pivot.Update 
    Next 
Next 

Answer 2

Sie haben eine Pivot-Tabellen Sammlung auf einem der VB Arbeitsblatt Objekt. Also, eine kurze Schleife wie dies funktioniert:

Sub RefreshPivotTables() 
    Dim pivotTable As PivotTable 
    For Each pivotTable In ActiveSheet.PivotTables 
     pivotTable.RefreshTable 
    Next 
End Sub 

Hinweise aus den Gräben:

1. Denken Sie daran, alle geschützten Blätter aufzuheben, bevor Sie die Pivot-Tabelle zu aktualisieren.
2. Oft speichern.
3. ich mehr und Update zu gegebener Zeit denken werde ... :)

Viel Glück!

Answer 3

Dieser VBA-Code aktualisiert alle Pivot-Tabellen/Diagramme in der Arbeitsmappe.

Sub RefreshAllPivotTables() 

Dim PT As PivotTable 
Dim WS As Worksheet 

    For Each WS In ThisWorkbook.Worksheets 

     For Each PT In WS.PivotTables 
      PT.RefreshTable 
     Next PT 

    Next WS 

End Sub 

Eine weitere nicht-programatic Option ist:

• Rechtsklick auf jeder Pivot-Tabelle
• Tabelle auswählen Optionen
• Tick die 'Aktualisieren auf open' Option.
• Klicken Sie auf die Schaltfläche OK

Dies wird die Pivot-Tabelle jedes Mal aktualisieren die Arbeitsmappe geöffnet wird.

Answer 4

In der Pivot-Tabellen-Symbolleiste gibt es die Option refresh all. Das genügt. Ich muss nichts anderes tun.

Drücken Sie Strg + Alt + F5

Answer 5

Unter bestimmten Umständen könnten Sie zwischen einer Pivot-Tabelle und ihre Pivotcache zu differenzieren wollen. Der Cache verfügt über eine eigene Aktualisierungsmethode und eigene Sammlungen. Wir hätten also alle PivotCaches anstelle der PivotTables aktualisieren können.

Der Unterschied? Wenn Sie eine neue Pivot-Tabelle erstellen, werden Sie gefragt, ob Sie eine neue Pivot-Tabelle basierend auf einer vorherigen Tabelle erstellen möchten. Wenn Sie Nein sagen, erhält diese Pivot-Tabelle einen eigenen Cache und verdoppelt die Größe der Quelldaten. Wenn Sie "Ja" sagen, behalten Sie Ihr WorkBook klein, aber Sie fügen es zu einer Sammlung von Pivot-Tabellen hinzu, die sich einen einzigen Cache teilen. Die gesamte Sammlung wird aktualisiert, wenn Sie eine einzelne Pivot-Tabelle in dieser Sammlung aktualisieren. Sie können sich also vorstellen, wie groß der Unterschied zwischen dem Aktualisieren jedes Caches im Arbeitsbuch und dem Aktualisieren jeder Pivot-Tabelle im Arbeitsbuch sein könnte.

Answer 6

Wenn Sie MS Excel 2003 verwenden, dann gehen Sie zu Ansicht-> Werkzeugleiste-> Pivot-Tabelle Von dieser Symbolleiste können wir aktualisieren, indem Sie auf klicken!dieses Symbol.

Answer 7

Ich habe den Befehl in der jüngsten Vergangenheit verwendet, und es scheint zu funktionieren.

ActiveWorkbook.RefreshAll 

Hoffe, dass hilft.

Answer 8

ActiveWorkbook.RefreshAll aktualisiert alles, nicht nur die Pivot-Tabellen, sondern auch die ODBC-Abfragen. Ich habe ein paar VBA-Abfragen, die zu Datenverbindungen beziehen und als Befehl dieser Option Abstürze mit laufen die Datenverbindungen ohne die Details aus dem VBA geliefert

empfehle ich die Option, wenn Sie nur die Zapfen wollen aktualisiert

Sub RefreshPivotTables()  
    Dim pivotTable As PivotTable  
    For Each pivotTable In ActiveSheet.PivotTables   
    pivotTable.RefreshTable  
    Next 
End Sub 

Answer 9

Der Code

Private Sub Worksheet_Activate() 
    Dim PvtTbl As PivotTable 
     Cells.EntireColumn.AutoFit 
     For Each PvtTbl In Worksheets("Sales Details").PivotTables 
     PvtTbl.RefreshTable 
     Next 
End Sub 

funktioniert gut.

Der Code wird im Aktivierungsblattmodul verwendet und zeigt daher ein Flimmern/Glitch an, wenn das Blatt aktiviert wird.

Answer 10

Sogar können wir bestimmte Verbindung aktualisieren und im Gegenzug wird es alle damit verbundenen Pivots aktualisieren.

Für diesen Code I Slicer aus der Tabelle in Excel erstellt haben:

Sub UpdateConnection() 
     Dim ServerName As String 
     Dim ServerNameRaw As String 
     Dim CubeName As String 
     Dim CubeNameRaw As String 
     Dim ConnectionString As String 

     ServerNameRaw = ActiveWorkbook.SlicerCaches("Slicer_ServerName").VisibleSlicerItemsList(1) 
     ServerName = Replace(Split(ServerNameRaw, "[")(3), "]", "") 

     CubeNameRaw = ActiveWorkbook.SlicerCaches("Slicer_CubeName").VisibleSlicerItemsList(1) 
     CubeName = Replace(Split(CubeNameRaw, "[")(3), "]", "") 

     If CubeName = "All" Or ServerName = "All" Then 
      MsgBox "Please Select One Cube and Server Name", vbOKOnly, "Slicer Info" 
     Else 
      ConnectionString = GetConnectionString(ServerName, CubeName) 
      UpdateAllQueryTableConnections ConnectionString, CubeName 
     End If 
    End Sub 

    Function GetConnectionString(ServerName As String, CubeName As String) 
     Dim result As String 
     result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2" 
     '"OLEDB;Provider=SQLOLEDB.1;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";Use Procedure for Prepare=1;Auto Translate=True;Packet Size=4096;Use Encryption for Data=False;Tag with column collation when possible=False" 
     GetConnectionString = result 
    End Function 

    Function GetConnectionString(ServerName As String, CubeName As String) 
    Dim result As String 
    result = "OLEDB;Provider=MSOLAP.5;Integrated Security=SSPI;Persist Security Info=True;Initial Catalog=" & CubeName & ";Data Source=" & ServerName & ";MDX Compatibility=1;Safety Options=2;MDX Missing Member Mode=Error;Update Isolation Level=2" 
    GetConnectionString = result 
End Function 

Sub UpdateAllQueryTableConnections(ConnectionString As String, CubeName As String) 
    Dim cn As WorkbookConnection 
    Dim oledbCn As OLEDBConnection 
    Dim Count As Integer, i As Integer 
    Dim DBName As String 
    DBName = "Initial Catalog=" + CubeName 

    Count = 0 
    For Each cn In ThisWorkbook.Connections 
     If cn.Name = "ThisWorkbookDataModel" Then 
      Exit For 
     End If 

     oTmp = Split(cn.OLEDBConnection.Connection, ";") 
     For i = 0 To UBound(oTmp) - 1 
      If InStr(1, oTmp(i), DBName, vbTextCompare) = 1 Then 
       Set oledbCn = cn.OLEDBConnection 
       oledbCn.SavePassword = True 
       oledbCn.Connection = ConnectionString 
       oledbCn.Refresh 
       Count = Count + 1 
      End If 
     Next 
    Next 

    If Count = 0 Then 
     MsgBox "Nothing to update", vbOKOnly, "Update Connection" 
    ElseIf Count > 0 Then 
     MsgBox "Update & Refresh Connection Successfully", vbOKOnly, "Update Connection" 
    End If 
End Sub