Teil einer Textdatei in BAT extrahieren

Question

Ich nehme eine M3U-Datei auf einer täglichen Basis auf, möchte aber einen Teil davon in eine andere Datei mit den wenigen Kanälen, die ich brauche, analysieren.

Zum Beispiel habe ich meine m3U umbenannte Datei in TEST.TXT, die folgende fiktive Struktur sagen hat:

die Linie von „#EXTINF starrte erfassen

#EXTINF:0,ABC 
#live link 1 
#EXTINF:0,XYZ 
#live link 2 
#EXTINF:0,UVW 
#live link 3 

Ich möchte nur sagen: 0, XYZ“und sagen sie die Zeile darunter mit einem Output.txt am Ende wie folgt:

#EXTINF:0,XYZ 
#live link 2 

Ich weiß, dass man die For-Schleife benutzen muss, aber ich bin ein bisschen noob in diesem Bereich.

Answer 1

ich es so tun würde, ist die .m3u Datei angenommen nicht wissen Räume in den Zeilen mit vorangestellten #EXTINF enthalten Hinter, wie Ihre Beispieldaten haben:

@echo off 
setlocal EnableExtensions DisableDelayedExpansion 

rem // Define constants here: 
set "FILE=%~1" 
set "HEADER=#EXTM3U" 
set "PREFIX=#EXTINF" 
set "MATCH=%~2" 

set "FLAG=" 
for /F usebackq^ delims^=^ eol^= %%L in ("%FILE%") do (
    if defined FLAG (
     echo(%%L 
     set "FLAG=" 
    ) 
    for /F "delims=:" %%P in ("%%L") do (
     if "%%P"=="%HEADER%" (
      echo(%%L 
     ) else if "%%P"=="%PREFIX%" (
      set "LINE=%%L" 
      setlocal EnableDelayedExpansion 
      if /I "!LINE:*,=!"=="!MATCH!" (
       echo(!LINE! 
       endlocal 
       set "FLAG=#" 
      ) else endlocal 
     ) 
    ) 
) 

endlocal 
exit /B 

Rufen Sie das Skript wie folgt, es angenommen wird als extract-entry.bat gespeichert:

extract-entry.bat "input_file.m3u" "XYZ" > "output_file.m3u" 

Das Skript für Zeile der gegebenen .m3u Dateizeile geht durch. Sie gibt die aktuelle Zeile unbearbeitet zurück und setzt die Variable FLAG zurück, wenn die Variable FLAG gesetzt ist, was am Anfang nicht der Fall ist.

Dann sucht es nach #EXTINF. Wenn gefunden (z. B. #EXTINF:0,XYZ), wird die Zeichenfolge nach dem Komma (XYZ) mit der angegebenen Suchzeichenfolge verglichen. Bei Übereinstimmung wird die aktuelle Zeile ausgegeben und FLAG Variable wird jetzt gesetzt, um auch die folgende Zeile zu erhalten.

Die Kopfzeile #EXTM3U wird immer ausgegeben.

Das Umschalten delayed expansion macht dieses Skript robust gegenüber allen Zeichen, die eine besondere Bedeutung für den Befehlsinterpreter haben, ohne sie zu verlieren.

Answer 2

Setzen Sie diesen Code in die Datei filter.cmd.

@echo off 
set INPUT=%1&set MATCH=%2& set MATCHED=0 
for /f "delims=" %%a in (%INPUT%) do call :line "%%~a" 
goto :eof 
:line 
set EXT=&TITLE=& 
for /f "tokens=1 delims=:" %%a in ("%~1") do set EXT=%%~a 
for /f "tokens=1,2,* delims=:," %%a in ("%~1") do set TITLE=%%~c 
if "%EXT%" == "#EXTM3U" echo %~1 
if "%EXT%" == "#EXTINF" (
    set MATCHED=0 
    echo %TITLE%| findstr /l %MATCH% >nul && set MATCHED=1 
) 
if %MATCHED%==1 echo %~1 

Anwendungsbeispiel:

filter.cmd input_file.m3u XYZ > output_file.m3u 

Hier ist eine Erklärung:
Jede Eingangsleitung geteilt wird unter Verwendung für/f mit Token und delims. MATCHED wird gesetzt, wenn die Zeile mit #EXTINF beginnt und der Rest die passende Zeichenfolge enthält (zweites Argument). Wenn MATCHED gesetzt ist, werden die Zeilen bis zum nächsten #EXTINF ausgegeben.