Android.bat Datei fehlt in sdk \ Tools Ordner auch ich habe keine AVD & SDK-Manager in Tools, so kann ich sie ersetzen

Question

Ich habe auch android.bat von meinem Backup-SDK kopiert, aber es funktioniert immer noch nicht. danke im voraus.

Answer 1

Wahrscheinlich fehlen alle die Inhalte der sdk/tools Ordner wie Gut?

Die beste Methode, um dieses Problem zu lösen, ist es, zum Ordner sdk/temp zu gehen. Dort finden Sie eine Zip-Datei mit einem Namen wie "tools_r24.0.1-windows" (Versionsnummer wird anders sein)

Kopieren Sie es an einen beliebigen Ort und extrahieren Sie es. Im Inneren des extrahierten Ordner haben Sie einen Ordner mit dem Namen

Copy ‚Tools‘, die SDK-Ordner/und den aktuellen Tools Ordner in sdk ersetzen/

Und voila! SDK und AVD funktionieren wieder und alle Ihre virtuellen Geräte werden wiederhergestellt!

Answer 2

ich nicht wirklich verstehen, warum Sie es von woanders nicht herunterladen, aber hier ist die Android.bat:

@echo off 
rem Copyright (C) 2007 The Android Open Source Project 
rem 
rem Licensed under the Apache License, Version 2.0 (the "License"); 
rem you may not use this file except in compliance with the License. 
rem You may obtain a copy of the License at 
rem 
rem  http://www.apache.org/licenses/LICENSE-2.0 
rem 
rem Unless required by applicable law or agreed to in writing, software 
rem distributed under the License is distributed on an "AS IS" BASIS, 
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. 
rem See the License for the specific language governing permissions and 
rem limitations under the License. 

rem Useful links: 
rem Command-line reference: 
rem http://technet.microsoft.com/en-us/library/bb490890.aspx 

rem don't modify the caller's environment 
setlocal 

rem Set up prog to be the path of this script, including following symlinks, 
rem and set up progdir to be the fully-qualified pathname of its directory. 
set prog=%~f0 

rem Grab current directory before we change it 
set work_dir=%cd% 

rem Change current directory and drive to where the script is, to avoid 
rem issues with directories containing whitespaces. 
cd /d %~dp0 


rem Check we have a valid Java.exe in the path. 
set java_exe= 
call lib\find_java.bat 
if not defined java_exe goto :EOF 

set jar_path=lib\sdkmanager.jar;lib\swtmenubar.jar 

rem Set SWT.Jar path based on current architecture (x86 or x86_64) 
for /f "delims=" %%a in ('"%java_exe%" -jar lib\archquery.jar') do set swt_path=lib\%%a 

:MkTempCopy 
    rem Copy android.bat and its required libs to a temp dir. 
    rem This avoids locking the tool dir in case the user is trying to update it. 

    set tmp_dir=%TEMP%\temp-android-tool 
    xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul 
    copy /B /D /Y lib\common.jar   %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\commons-codec*  %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\commons-compress* %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\commons-logging* %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\dvlib.jar   %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\guava*    %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\httpclient*  %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\httpcore*   %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\httpmime*   %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\layoutlib-api.jar %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\org-eclipse-*  %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\sdk*    %tmp_dir%\lib\  > nul 
    copy /B /D /Y lib\swtmenubar.jar  %tmp_dir%\lib\  > nul 

    rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs. 
    set tools_dir=%cd% 
    cd /d %tmp_dir% 

:EndTempCopy 

rem The global ANDROID_SWT always override the SWT.Jar path 
if defined ANDROID_SWT set swt_path=%ANDROID_SWT% 

if exist "%swt_path%" goto SetPath 
    echo ERROR: SWT folder '%swt_path%' does not exist. 
    echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform. 
    goto :EOF 

:SetPath 
rem Finally exec the java program and end here. 
REM set REMOTE_DEBUG=-Xdebug -Xrunjdwp:transport=dt_socket,server=y,suspend=y,address=8000 
call "%java_exe% %REMOTE_DEBUG%" "-Dcom.android.sdkmanager.toolsdir=%tools_dir%" "-Dcom.android.sdkmanager.workdir=%work_dir%" -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %* 

rem EOF 

Answer 3

die beste Lösung, ich habe, ist die SDK-Tools herunterladen Nur Von:.. http://developer.android.com/sdk/index.html

-> Andere Download-Optionen-> SDK Werkzeuge Only-> Android-sdk_r24 * * - windows.zip . und extrahieren Sie es in Ihre SDK-Position, wo die Werkzeuge benötigt werden.

Answer 4

Ich habe das Android Studio Bundle heruntergeladen (android-studio-bundle-143.2915827-windows.exe), dann habe ich das mit 7Zip geöffnet und im $ TEMP-Verzeichnis befindet sich eine android-sdk.7z-Datei. Ich extrahierte das und kopierte den Tools-Ordner zurück.

Ich war nicht sicher, wie ich es gelöscht hätte, aber ich habe einen dieser HiDpi-Bildschirme, und als ich den SDK-Manager öffnete, dachte ich, ich würde Klicken Sie auf die Schaltfläche "Aktualisieren", aber es stellt sich heraus, dass Sie nicht das ganze Wort sehen können, und es ist tatsächlich die Schaltfläche "Löschen".

Warum genau ein Werkzeug zur Selbst Löschung erlaubt ist ich .....