Wie sieht man den Typ einer Variablen in PL/SQL?

Question

Gibt es in PL/SQL eine Funktion, um den genauen Typ einer Variablen anzuzeigen, wie die DUMP-Funktion in SQL?

Ich habe versucht, die folgende

DECLARE 
    l_variable INTEGER := 1; 
BEGIN 
    DBMS_OUTPUT.PUT_LINE (DUMP (l_variable)); 
END; 

Aber es gibt den folgenden Fehler:

PLS-00204: function or pseudo-column 'DUMP' may be used inside a SQL statement only

Answer 1

Sie diese Funktion PL/Scope mit erstellen können. Aber es funktioniert nicht mit anonymen Blöcken und Sie müssen die Variable als String referenzieren.

create or replace function get_plsql_type_name 
(
    p_object_name varchar2, 
    p_name varchar2 
) return varchar2 is 
    v_type_name varchar2(4000); 
begin 
    select reference.name into v_type_name 
    from user_identifiers declaration 
    join user_identifiers reference 
     on declaration.usage_id = reference.usage_context_id 
     and declaration.object_name = reference.object_name 
    where 
     declaration.object_name = p_object_name 
     and declaration.usage = 'DECLARATION' 
     and reference.usage = 'REFERENCE' 
     and declaration.name = p_name; 

    return v_type_name; 
end; 
/

Beispiel:

alter session set plscope_settings = 'IDENTIFIERS:ALL'; 

create or replace type my_weird_type is object 
(
    a number 
); 

create or replace procedure test_procedure is 
    var1 number; 
    var2 integer; 
    var3 my_weird_type; 
    subtype my_subtype is pls_integer range 42 .. 43; 
    var4 my_subtype; 
begin 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR1')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR2')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR3')); 
    dbms_output.put_line(get_plsql_type_name('TEST_PROCEDURE', 'VAR4')); 
end; 
/

begin 
    test_procedure; 
end; 
/

NUMBER 
INTEGER 
MY_WEIRD_TYPE 
MY_SUBTYPE 

Answer 2

declare 
    a number(10,3); 
    type_info varchar2(400); 
begin 
    a := 55.5; 
    select dump(a) into type_info from dual; 
    DBMS_OUTPUT.PUT_LINE(type_info); 
end; 

Answer 3

wie Sie feststellen sollten, DUMP ist eine überladene Funktion. es hat 3 Überladungen.

So können Sie das gleiche in Ihrem Code simulieren.

Der obige Code funktioniert möglicherweise nicht richtig, aber sollte Ihnen die Idee geben, wie Sie das Problem lösen.

Ich hoffe, dass dies Ihre Anforderungen erfüllen wird.

Hinweis; Sie können diese Funktionen in ein Paket einfügen und entsprechend verwenden.