API zum Ermitteln, ob App auf Citrix oder Terminaldienste ausgeführt wird

Question

Ich bin auf der Suche nach einer API/Funktion, die ich aufrufen kann, um festzustellen, ob Software auf Citrix, Terminal Services oder einem eigenständigen PC ausgeführt wird. Optimal wäre es so etwas wie dies funktioniert:

Select Case APIWhatSystem.Type.ToString 
    Case "Citrix" 
     bCitrix = True 
    Case "TS" 
     bTerminalServices = True 
    Case "PC" 
     bPC = True 
End Select 

Ich würde lieber etwas, das von einem API-Aufruf arbeitete als auf dem Blick auf etwas in der Registrierung im Gegensatz wir immer mehr Kunden mit, die die Registrierung sind Sperren .

Danke.

Answer 1

Gemäß: http://forums.citrix.com/message.jspa?messageID=1363711 können Sie die Umgebungsvariable SESSIONNAME überprüfen.

Eine andere einfachere Möglichkeit ist das Lesen der Systemumgebungsvariablen "SESSIONNAME". Wenn es existiert und mit "ICA" beginnt, dann laufen Sie innerhalb einer Citrix Sitzung. Wenn es mit "RDP" beginnt, dann laufen Sie innerhalb einer RDP-Sitzung.

Getestet habe ich es mit meinem PC und lokal erhalte ich:

C:\>echo %SESSIONNAME% 
Console 

Während der Ferne habe ich

C:\>echo %SESSIONNAME% 
RDP-tcp1 

So scheint es, wie es ein einfacher Weg sein könnte zu gehen, es anders klingt wie nach Registrierungswerten zu suchen oder wenn bestimmte dlls existieren, ist die nächstbeste Sache.

Answer 2

Nach @ Joshs Antwort, würde der Code wie folgt aussehen:

Select Case Environment.GetEnvironmentVariable("SessionName").ToUpper.SubString(0,3)) 
    Case "ICA" 
     bCitrix = True 
    Case "RDP" 
     bTerminalServer = True 
    Case "CON" 
     bPC = True 
End Select 

Ich habe nicht voll es noch nicht getestet, aber es sieht aus wie es das tun, was ich will. PCs und Terminalserver meldet korrekt.

Wenn jemand eine Möglichkeit hat, dies auf einer Citrix-Box zu testen, wäre es sehr zu empfehlen!

Answer 3

Es gibt eine API-Funktion, mit der Sie bestimmen können, ob eine bestimmte Benutzersitzung auf der Konsole angezeigt wird (lokal) oder über eines der Remoting-Protokolle Citrix ICA (heute HDX) oder Microsoft RDP.

Rufen Sie WTSQuerySessionInformation mit 3. Parameter auf WTSClientProtocolType. Die Funktion gibt:

• 0 für Konsolensitzungen
• 1 für ICA-Sitzungen
• 2 für RDP-Sitzungen

Interessanter der Rückgabewert von 1 ist nicht als WTS_PROTOCOL_TYPE_ICA auf MSDN (zweite Verbindung dokumentiert oben) nicht mehr, sondern als "Dieser Wert wird für ältere Zwecke beibehalten.".

Update:

XenDesktop Sitzungen können nicht mit WTSQuerySessionInformation nachgewiesen werden (es gibt 0 zurück, was bedeutet, Console).Wenn Sie eine universelle Lösung wünschen:

• Anruf WTSQuerySessionInformation. Wenn das 1 oder 2 (ICA oder RDP) zurückgibt, sind Sie fertig.
• Wenn WTSQuerySessionInformation 0 zurück (Konsole), dynamisch laden wfapi.dll und erhält die Adresse WFGetActiveProtocol
• Anruf WFGetActiveProtocol mit einem Parameter von WF_CURRENT_SESSION, die definiert ist als ((DWORD) -1)
• Der Rückgabewert von WFGetActiveProtocol ist der Sitzungstyp. Es sollte entweder 0 (Konsole) oder 1 (ICA)

sein ich den Prozess im Detail beschrieben wurden here zusammen mit einem C++ Code Probe und einer Arbeits kompilierten Werkzeug, das der aktuellen Sitzung des remoting Protokolltyp zurückgibt.

Answer 4

Basierend auf Helge Keins überarbeiteter Antwort (oben) dachte ich, ich würde den VBA-Code veröffentlichen, um dies zu ermöglichen, damit zukünftige VBA-Benutzer diese Seite erreichen können. Helge hat bereits den C++ Code auf seiner eigenen Seite. Wenn Sie dies hilfreich finden, bitten wir Sie, Helge Klein zu antworten.

Option Explicit 

Private Const WTS_CURRENT_SERVER_HANDLE = 0& 
Private Const WTS_CURRENT_SESSION As Long = -1 

Private Enum WTS_INFO_CLASS 
    WTSInitialProgram 
    WTSApplicationName 
    WTSWorkingDirectory 
    WTSOEMId 
    WTSSessionId 
    WTSUserName 
    WTSWinStationName 
    WTSDomainName 
    WTSConnectState 
    WTSClientBuildNumber 
    WTSClientName 
    WTSClientDirectory 
    WTSClientProductId 
    WTSClientHardwareId 
    WTSClientAddress 
    WTSClientDisplay 
    WTSClientProtocolType 
    WTSIdleTime 
    WTSLogonTime 
    WTSIncomingBytes 
    WTSOutgoingBytes 
    WTSIncomingFrames 
    WTSOutgoingFrames 
    WTSClientInfo 
    WTSSessionInfo 
    WTSSessionInfoEx 
    WTSConfigInfo 
    WTSValidationInfo 
    WTSSessionAddressV4 
    WTSIsRemoteSession 
End Enum 

Private Declare Function WTSQuerySessionInformation _ 
    Lib "wtsapi32.dll" Alias "WTSQuerySessionInformationA" (_ 
    ByVal hServer As Long, ByVal SessionId As Long, _ 
    ByVal WtsInfoClass As WTS_INFO_CLASS, _ 
    ByRef ppBuffer As LongPtr, _ 
    ByRef pBytesReturned As LongPtr _ 
    ) As Long 

Private Declare Function WFGetActiveProtocol _ 
    Lib "wfapi.dll" (_ 
    ByVal SessionId As Long _ 
    ) As Long 

Private Declare Sub WTSFreeMemory Lib "wtsapi32.dll" (_ 
    ByVal pMemory As Long) 

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (_ 
    Destination As Any, Source As Any, ByVal length As Long) 

Public Function SessionType() As String 
    Dim ResultCode As Long 
    Dim p As LongPtr 
    Dim ppBuffer As LongPtr 
    Dim pBytesReturned As Long 
    Dim ClientProtocolType As Integer 
    ResultCode = WTSQuerySessionInformation(WTS_CURRENT_SERVER_HANDLE, WTS_CURRENT_SESSION, WTSClientProtocolType, ppBuffer, pBytesReturned) 

    If ResultCode = 0 Then 
     p = ppBuffer 
     CopyMemory ClientProtocolType, ByVal p, pBytesReturned 
     WTSFreeMemory ppBuffer 
    End If 

    Select Case ClientProtocolType 
     Case 0: 
     On Error Resume Next 
     ResultCode = WFGetActiveProtocol(WTS_CURRENT_SESSION) 
     If Err.Number = 53 Then 
      SessionType = "Console" 
     ElseIf Err.Number = 0 Then 
      If ResultCode = 1 Then 
      SessionType = "Citrix" 
      Else 
      SessionType = "Console" 
      End If 
     End If 
     Err.Clear 
     On Error GoTo 0 
     Case 1: 
     SessionType = "Citrix" 
     Case 2: 
     SessionType = "RDP" 
     Case Else 
     SessionType = "Other (" & ClientProtocolType & ")" 
    End Select 
End Function 

Ich habe dies auf XenApp und XenDesktop getestet.