VBA Für die nächste Schleife bis zur letzten Zeile einer Spalte, aber nicht letzte Zeile des Blattes

Question

Ich versuche, eine For Next Loop bis zur letzten Zeile einer bestimmten Spalte (aber nicht die letzte Zeile des Blattes) auszuführen. Der erste Teil meiner Liste hat also Daten in Spalte F und der zweite Teil nicht. Ich möchte nur, dass das Makro auf diesen ersten Teil angewendet wird. Aus irgendeinem Grund läuft die Schleife nur mit bestimmten Befehlen durch den ersten Teil, aber nicht mit denen, die ich gerade versuche. (Ich weiß, es wäre einfach, die zwei Teile manuell zu trennen und dann zu laufen, aber es macht mich verrückt, nicht zu wissen, was ich falsch gemacht habe :)). Diese

ist der Code:

Dim i As Integer 
Dim g As Double 
g = 0.083333333 
Dim lastrow As Long 
lastrow = Sheets("zm").Range("f" & Rows.Count).End(xlUp).Row 

Sheets("zm").Activate 

For i = 2 To lastrow 

    If Sheets("zm").Cells(i, 1) = Sheets("zm").Cells(i + 1, 1) And Sheets("zm").Cells(i, 5) = Sheets("zm").Cells(i + 1, 5) And Sheets("zm").Cells(i + 1, 6) - Sheets("zm").Cells(i, 7) < g Then 
     Sheets("zm").Cells(i + 1, 7).Copy 
     Sheets("zm").Cells(i, 7).Select 
     ActiveSheet.Paste 
     Application.CutCopyMode = False 
     Sheets("zm").Rows(i + 1).Delete 
    End If 

Next i 

Vielen Dank für Ihre Hilfe!

Answer 1

vermeiden Select/Selection und/oder Activate/ActiveXXX

versuchen Sie dies:

Option Explicit 

Sub main() 
    Dim i As Long, lastrow As Long 
    Dim g As Double 
    g = 0.083333333 

    With Worksheets("zm") 
     lastrow = .Cells(.Rows.Count, "F").End(xlUp).Row 

     For i = lastrow To 2 Step -1 
      If .Cells(i, 1) = .Cells(i + 1, 1) And .Cells(i, 5) = .Cells(i + 1, 5) And .Cells(i + 1, 6) - .Cells(i, 7) < g Then 
       .Cells(i + 1, 7).Copy Destination:=.Cells(i, 7) 
       .Rows(i + 1).Delete 
      End If 
     Next i 
    End With 
End Sub