Gibt es eine Möglichkeit, die Druckausgabe einer Unterroutine auf eine Variable zu erfassen, damit ich sie stattdessen an stderr senden kann?

Question

Angenommen, wir haben:

sub test { 
     print "testing\n"; 
} 

Wenn es einen Fall gibt, wo ich es statt stdout zu stderr gedruckt haben wollen, ist es eine Möglichkeit, das Unterprogramm, dies zu tun anrufen können? Oder kann ich die Ausgabe auf eine Variable erfassen und dann warnen? Ich bin ziemlich neu in Perl.

Answer 1

Ja, da ist. print sendet seine Ausgabe an das "ausgewählte" Dateihandle, das normalerweise STDOUT ist. Aber Perl bietet die select Funktion für Sie, um es zu ändern.

select(STDERR); 
&test;   # send output to STDERR 
select(STDOUT); # restore default output handle 

Die select Funktion gibt die zuvor ausgewählte Dateihandle, so können Sie es erfassen und später wiederherstellen.

my $orig_select = select(STDERR); 
&test; 
select($orig_select); 

Answer 2

Perl dynamische Scoping über local() nicht oft verwendet wird, aber dies scheint mir eine gute Anwendung für sie:

test(); # to stdout 
{ 
    open(local *STDOUT, ">&STDERR") or die "dup out to err: $!"; 
    test(); # to stderr, locally calling it "STDOUT" 
} 
test(); # to stdout again 

Der Aufruf von test() im Block oben - sowie alles dass test() selbst aufrufen könnte - STDOUT wird dynamisch auf Ihr Duplikat von STDERR beschränkt. Wenn die Steuerung den Block verlässt, auch wenn durch die() ing wird STDOUT, was auch immer wieder hergestellt werden war es vor dem Block

generali:

sub out2err(&) { 
    my $user_block = shift; 
    open(local *STDOUT, ">&STDERR") or die $!; 
    $user_block->(); 
} 

test();    # to stdout 
out2err { test() }; # to stderr 
test();    # to stdout 

Answer 3

der Zwischenzeit können Sie auch „Aufnehmen eines Druckausgabe des Unterprogramm auf eine Variable . "

einfach einen skalaren ref open passieren:

#! /usr/bin/env perl 
use common::sense; 
use autodie; 

sub tostring (&) { 
    my $s; 
    open local *STDOUT, '>', \$s; 
    shift->(); 
    $s 
} 

sub fake { 
    say 'lalala'; 
    say 'more stuff'; 
    say 1 + 1, ' = 2'; 
    say for @_; 
} 

for (tostring { fake(1, 2, 3) }) { 
    s/\n/\\n/g; 
    say "Captured as string: >>>$_<<<"; 
} 

Ausgang:

Captured as string: >>>lalala\nmore stuff\n2 = 2\n1\n2\n3\n<<<