Entfernen von Werten aus Satz im Batch

Question

Ich versuche, ein Skript für die Arbeit zu schreiben, die mir sagt, welche Maschinen in einem Netzwerk online und welche offline sind.

Momentan habe ich es online/offline Status zeigen, die PC-Namen aus einer Textdatei als Eingabe in eine Set-Variable.

Der Code, den ich bisher habe, ist:

@echo off 
setlocal EnableDelayedExpansion 

for /F "tokens=*" %%a in (VC.txt) do call :append %%a 

:ping 
for %%i in (%VC) do (
ping %%1 -n 1 >nul 
call :test %%i 
) 
echo. 
goto :ping 

:test 
IF %ERRORLEVEL% EQU 0 (
echo Pinging %1 
) else (
echo Off %1 
) 
goto :eof 

:append 
if defined VC (
set VC=%VC% %1 
) else (
set VC=%1 
) 

Was will ich einmal geschehen ist ein Gerät online geht, ist es aus der Liste zu entfernen. Im Grunde nur zeigen Sie nur die Liste der Offline-Maschinen. Ist das möglich, ohne das ganze Set zu wischen und frisch zu machen?

Answer 1

Dieser Mod zu tun, was Sie wollen:

:test 
IF %ERRORLEVEL% EQU 0 (
echo Pinging %1 
REM Remove this machine from the list 
set "VC=!VC: %1=!" 
) else (
echo Off %1 
) 
goto :eof 

Sie jedoch ein paar kleine Fehler in Ihrem Code haben. Dies ist der feste Abschnitt:

:ping 
for %%i in (%VC%) do (
ping %%i -n 1 >nul 
call :test %%i 
) 
echo. 
goto :ping 

Ein paar Punkte, die nichts mit Ihrem Problem zu tun haben. Wenn die Computernamen einzelne Wörter ohne Leerzeichen sind, wird der "tokens=*" Teil im Befehl for nicht benötigt. Auch all diese call 's und Subroutinen erschweren nur den Code. Dies ist die Art und Weise, wie ich dies tun würde:

@echo off 
setlocal EnableDelayedExpansion 

set "VC=" 
for /F %%a in (VC.txt) do set "VC=!VC! %%a" 

:ping 
for %%i in (%VC%) do (
    ping %%i -n 1 >nul 
    IF !ERRORLEVEL! EQU 0 (
     echo Pinging %%i 
     REM Remove this machine from the list 
     set "VC=!VC: %%i=!" 
    ) else (
     echo Off %%i 
    ) 
) 
echo/ 
if defined VC goto :ping 

echo All machines are on line