Common Lisp - Funktion auf jedes andere Element in der Liste anwenden

Question

Ich möchte die Funktion (* x 2) auf jedes andere Element in einer Liste anwenden und die gesamte Liste mit dem Makro loop zurückgeben. Die Lösung, die ich mit so weit habe kommen, ist dies:

(defun double-every-other (xs) 
    (loop for x in xs by #'cddr collect (* x 2))) 

Dies wird jedoch doppelt jedes andere Element und nur die Elemente zurück, die verdoppelt wurden, also wenn ich ausgeführt:

(double-every-other '(1 2 3 4)) 

Die Ergebnis wäre:

'(4 8) 

Aber ich will das Ergebnis sein:

'(1 4 3 8) 

Gibt es eine Möglichkeit, dies mit (Schleife) zu tun?

Answer 1

Sie können zum Beispiel Erhöhung eine ganze Zahl testen, während die Liste durchsucht:

(defun double-every-other (xs) 
    (loop for x in xs 
    for i from 1 
    if (oddp i) 
    collect x 
    else collect (* x 2))) 

Answer 2

Eine andere Version mit weniger Mathematik:

(defun double-every-other (list) 
    (loop 
    for (a b) on list by #'cddr 
    collect a 
    when b collect (* b 2))) 

(double-every-other '(1 2 3 4)) 
=> (1 4 3 8) 

(double-every-other '(1 2 3 4 5)) 
=> (1 4 3 8 5) 

Offensichtlich werden Sie nicht zu abstrahieren die N Lage sein so leicht wie die andere Antwort (wenn Sie "Makro" denken, hören Sie jetzt auf). Hier durchlaufen wir das Schlüsselwort on, was bedeutet, dass jede Unterliste der Reihe nach besucht wird. Da wir by #'cddr verwenden, wird jede andere Unterliste übersprungen. Die Destrukturierungssyntax (a b) bindet das erste und zweite Element der besuchten Liste.

Answer 3

(defun double-every-other (xs) 
    (loop for x in xs 
     for doublep = nil then (not doublep) 
     collect (if doublep (* x 2) x))) 

Answer 4

eine andere Version, ohne Schleife überhaupt:

(defun make-cycled (&rest items) 
    (setf (cdr (last items)) items)) 

(mapcar #'funcall 
     (make-cycled #'identity (lambda (x) (* 2 x))) 
     '(10 9 8 7 6 5 4 3)) 

;;=> (10 18 8 14 6 10 4 6) 

Answer 5

Sie die loop primitive "auf" Liste Iteration verwenden könnte. Dies nimmt eine Liste von Schleifenvariablen auf, die über die Liste "verschmiert" werden, wobei die letzte der Rest der gesamten verbleibenden Liste ist. Die Bedingung loop für ist notwendig, um zu vermeiden, nil zu multiplizieren, wenn wir eine ungerade Anzahl von Argumenten haben.

(defun double-every-other (list) 
    (loop for (single double tail) on list by #'cddr 
    if (null double) 
     collect single 
    else 
     append (list single (* 2 double)))) 

Und wenn wir versuchen, es zu laufen:

* (double-every-other '(1 2 3 4 5)) 

(1 4 3 8 5)