Wie kann ich ein unsigned int aus einer Binärdatei in Perl lesen?

Question

Lassen Sie uns sagen, dass ich eine binäre Datei, die wie

[unsigned int(length of text)][text][unsigned int(length of text)][text][unsigned int(length of text)][text] 

Und dieses Muster für die Datei zu wiederholen immer wieder nur formatiert ist. Wie lese ich das unsigned int und drucke es aus, gefolgt von dem Textblock in Perl?

Auch dies ist eine Binärdatei und keine einfache Textdatei.

Answer 1

Hier ist ein kleines Arbeitsbeispiel.

#!/usr/bin/perl 

use strict; 
use warnings; 

my $INT_SIZE = 2; 
my $filename = 'somefile.bin'; 

open my $fh, '<', $filename or die "Couldn't open file $filename: $!\n"; 

binmode $fh; 

while (read $fh, my $packed_length, $INT_SIZE) { 

    my $text = ''; 
    my $length = unpack 'v', $packed_length; 

    read $fh, $text, $length; 

    print $length, "\t", $text, "\n"; 
} 

ändern INT_SIZE und die Größe und endianness der Entpackoperation Vorlage entsprechen (entweder 'v' oder 'n' oder 'V' oder 'N'). Weitere Informationen finden Sie in der Hilfeseite unpack.

Answer 2

Sie müssen die unpack Funktion für die Daten verwenden. Überprüfen Sie Pack/Unpack Tutorial (aka How the System Stores Data).

Dies sollten Sie in die richtige Richtung gehen (32 Bit angenommen wird):

#!/usr/bin/perl 

use strict; 

my $strBuf = "perl rocks"; 
my $packed = pack("I Z15", length($strBuf), $strBuf); 
{ 
    open(my $binFile, '>', "test.bin") || die("Error opening file\n"); 
    binmode $binFile; 
    print $binFile $packed; 
    close $binFile; 
} 


open(my $binFile, '<', "test.bin") || die("Error opening file\n"); 
binmode $binFile; 

my $buffer; 
read($binFile, $buffer, 4); ## Read out unsigned int binary data 
my $length = unpack("I", $buffer); ## Unpack the data 

read($binFile, $buffer, $length); ## Read the length out as binary 
my $string = unpack("Z$length", $buffer); ## Unpack the string data in buffer 

print "Len: $length String: $string\n"; 
exit; 

Answer 3

Zusätzlich unpack zu verwenden, als RC darauf hinweist, werden Sie mit ziemlicher Sicherheit read oder sysread verwenden möchten, Daten zu lesen aus der Datei.

Answer 4

Es gibt nicht wirklich genug Informationen hier, um dieses Problem vollständig zu lösen.

Benötigt wird das genaue Format des Längenfeldes und des Textfelds. Ist das int 2 Bytes, 4 Bytes oder 8 Bytes? (Alle sind möglich.) Ist es auch Little-Endian oder Big-Endian?

Anhand dieser Informationen greifen Sie dann mit der Lesefunktion auf die erste Ganzzahl zu und konvertieren sie mithilfe von Bitoperationen oder der Entpackfunktion in eine Zahl.

Das nächste Problem ist das genaue Format der Textzeichenfolge. Ist es ASCII, EBCDIC oder ein UTF-Format? Wenn Sie dies wissen, können Sie die Länge der Zeichenfolge berechnen und eine oder mehrere Leseoperationen verwenden, um die unbearbeitete Zeichenfolge zu erhalten, die Sie möglicherweise in eine besser verwaltbare Form konvertieren müssen.

Eine andere Sache - Sie müssen die Datei im Binärmodus öffnen, sonst erhalten Sie möglicherweise nicht die erwarteten Ergebnisse.