Empfangen des Event.COPY-Ereignisses in Flash

Question

Mein Ziel ist es zu wissen, wann ein Benutzer die Ausschnitte drückt, kopiert, einfügt oder alle Tastaturkürzel auswählt und einige Bearbeitungen für jeden ausführt. Ich habe versucht, auf die Tasten drücken, aber nur einige Tasten werden ausgelöst, wenn die Steuer-Taste gedrückt ist (anscheinend würde es nur im Browser funktionieren, außer für IE).

Dann las ich die Flash-Dokumente und stieß auf die Event.COPY, Event.PASTE und Event.CUT Ereignisse, die an das "Objekt, das derzeit Fokus hat". Ich habe Listener für diese Ereignisse an die Dokumentklasse angehängt und stage.focus auf die Dokumentklasse gesetzt, aber meine Ereignislistener werden nie aufgerufen.

Hat jemand diese Ereignisse verwendet? Gibt es irgendwo ein Beispiel, wie man sie benutzt?

Hinweis: Dies ist in Flash Player 10 (sowohl die interne CS4 eine (mit "Disable Shortcuts" abgehakt) und die Stand-alone-Version). Ich habe es in keinem Browser probiert.

Answer 1

Neben der Einschränkung, dass solche Ereignisse nicht von TextFields erfasst werden können (oder wenn der Fokus auf einem TextField liegt), stellen Sie sicher, dass die stage.focus -Eigenschaft tatsächlich auf das InteractiveObject gesetzt ist, an das Sie die Listener anhängen seiner Kinder (außer es ist ein Textfeld ^^).

Bedenken Sie, dass Sie den Fokus nur festlegen können, indem Sie die stage.focus-Eigenschaft direkt festlegen und indem Sie auf TabEnabled InteractiveObjects klicken oder eine Tabulatortaste drücken.

Answer 2

Nur der Vollständigkeit halber, hier ist die Klasse, die ich verwendet habe, um den Fokus auf ein paar Objekte auf einer "weißen Liste" gehen zu lassen, dann den Fokus auf ein Standardobjekt, wenn der Fokus von der verloren geht white-list-Objekt (es sei denn, es auf einen anderen white-List-Objekt geht):

/* 
Copyright (c) 2009, Cameron Desrochers 
All rights reserved. 

Redistribution and use in source and binary forms, with or without modification, are permitted 
provided that the following conditions are met: 

    * Redistributions of source code must retain the above copyright notice, this list of 
     conditions and the following disclaimer. 
    * Redistributions in binary form must reproduce the above copyright notice, this list 
     of conditions and the following disclaimer in the documentation and/or other materials 
     provided with the distribution. 

THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND 
ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED 
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE 
DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR 
ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES 
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; 
LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON 
ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT 
(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS 
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. 
*/ 


package 
{ 
    import fl.controls.ColorPicker; 
    import flash.display.DisplayObject; 
    import flash.display.InteractiveObject; 
    import flash.display.DisplayObjectContainer; 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.events.Event; 
    import flash.events.FocusEvent; 
    import flash.events.MouseEvent; 
    import flash.geom.Point; 
    import flash.utils.Dictionary; 



    public class FocusManager 
    { 
     public static var stage:Stage; 
     public static var defaultFocalObject:DisplayObjectContainer; 

     private static var _whiteList:Array = new Array(); 


     public static function init(stage:Stage, defaultFocalObject:DisplayObjectContainer):void 
     { 
      FocusManager.stage = stage; 
      FocusManager.defaultFocalObject = defaultFocalObject; 

      stage.addEventListener(MouseEvent.CLICK, onStageClicked); 

      defaultFocalObject.addEventListener(FocusEvent.FOCUS_OUT, onObjectFocusOut); 

      restoreDefaultFocus(); 
     } 


     public static function restoreDefaultFocus():void 
     { 
      stage.focus = defaultFocalObject; 
     } 


     public static function addToWhiteList(object:InteractiveObject):void 
     { 
      if (Object(object).constructor == ColorPicker) {  // Special case 
       // ColorPicker objects possess a textField that is for some reason not a child of the 
       // ColorPicker, and so the textField has to be added separately. 

       addToWhiteList(ColorPicker(object).textField); 
      } 

      _whiteList.push(object); 

      object.addEventListener(FocusEvent.FOCUS_OUT, onObjectFocusOut); 
      object.addEventListener(Event.REMOVED_FROM_STAGE, onObjectRemovedFromStage); 
     } 


     private static function onObjectFocusOut(e:FocusEvent):void 
     { 
      //trace('e.target:', e.target); 
      //trace('e.relatedObject:', e.relatedObject); 

      if ((e.relatedObject == null) || ((e.relatedObject !== defaultFocalObject) && (!whiteListContains(e.relatedObject)))) { 
       // Object that is gaining focus is not in white-list, restore focus: 

       //trace('restoring default focus'); 
       restoreDefaultFocus(); 
      } 
     } 


     private static function whiteListContains(object):Boolean 
     { 
      var inList:Boolean = false; 

      for each (var listItem in _whiteList) { 
       if ((object === listItem) || ((listItem.hasOwnProperty('contains')) && (listItem.contains(object)))) { 
        inList = true; 
        break; 
       } 
      } 

      return inList; 
     } 


     private static function onObjectRemovedFromStage(e:Event):void 
     { 
      restoreDefaultFocus(); 
     } 


     private static function onStageClicked(e:MouseEvent):void 
     { 
      var objectsUnderClick:Array = stage.getObjectsUnderPoint(new Point(stage.mouseX, stage.mouseY)); 

      var clickedOnWhiteListItem:Boolean = false; 
      for each (var object in objectsUnderClick) { 
       if (whiteListContains(object)) { 
        clickedOnWhiteListItem = true; 
        break; 
       } 
      } 

      if (!clickedOnWhiteListItem) { 
       restoreDefaultFocus(); 
      } 
     } 
    } 
} 

Rufen Sie die statische init Methode mit dem stage Objekts Dokumentenklasse und dem Objekt, das Sie den Fokus auf standardmäßig zurückgeben möchten. Fügen Sie dann Objekte zur Whitelist mit der statischen Methode addToWhitelist hinzu.