Dateien mit awk vergleichen

Question

Hallo Ich habe zwei ähnliche Dateien (beide mit 3 Spalten). Ich würde gerne überprüfen, ob diese beiden Dateien die gleichen Elemente enthalten (aber in einer anderen Reihenfolge aufgeführt). nur die ersten Spalten Zunächst einmal würde ich

file1.txt

"aba" 0 0 
"abc" 0 1 
"abd" 1 1 
"xxx" 0 0 

file2.txt

"xyz" 0 0 
"aba" 0 0 
"xxx" 0 0 
"abc" 1 1 

vergleichen wollen Wie kann ich es tun mit awk? Ich habe versucht, mich umzusehen, aber ich habe nur komplizierte Beispiele gefunden. Was, wenn ich auch die anderen beiden Spalten zum Vergleich hinzufügen möchte? Die Ausgabe sollte mir die Anzahl der übereinstimmenden Elemente geben.

Answer 1

Um die gemeinsamen Elemente in beiden Dateien zu drucken:

$ awk 'NR==FNR{a[$1];next}$1 in a{print $1}' file1 file2 
"aba" 
"abc" 
"xxx" 

Erläuterung:

NR und FNR sind awk Variablen, die die Gesamtzahl der Datensätze und die Anzahl der Datensätze in der aktuellen Dateien speichern bzw. (der Standard-Datensatz ist eine Zeile).

NR==FNR # Only true when in the first file 
{ 
    a[$1] # Build associative array on the first column of the file 
    next # Skip all proceeding blocks and process next line 
} 
($1 in a) # Check in the value in column one of the second files is in the array 
{ 
    # If so print it 
    print $1 
} 

Wenn Sie die ganze Linien passen wollen, dann verwenden $0:

$ awk 'NR==FNR{a[$0];next}$0 in a{print $0}' file1 file2 
"aba" 0 0 
"xxx" 0 0 

oder einen bestimmten Satz von Spalten:

$ awk 'NR==FNR{a[$1,$2,$3];next}($1,$2,$3) in a{print $1,$2,$3}' file1 file2 
"aba" 0 0 
"xxx" 0 0 

Answer 2

die Anzahl der passenden Elemente zu drucken, ist hier ein Weg mit awk:

awk 'FNR==NR { a[$1]; next } $1 in a { c++ } END { print c }' file1.txt file2.txt 

Ergebnisse Ihre Eingabe mit:

3 

---

Wenn Sie zusätzliche Spalten möchte hinzufügen (zum Beispiel Spalten ein, zwei und drei), verwenden Sie ein pseudo-multidimensional array:

awk 'FNR==NR { a[$1,$2,$3]; next } ($1,$2,$3) in a { c++ } END { print c }' file1.txt file2.txt 

Ergebnisse mit Ihrer Eingabe:

2