Convert Zeichenfolge "abc" zu $ ​​hash -> {a} -> {b} -> {c} in Perl

Question

Ich habe dynamische verschachtelte Hash-Refs wie folgt aus:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

ich festlegen möchten der Wert von c zu "etwas", indem dem Benutzer erlaubt wird, "abc etwas" einzugeben.

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

Aber wie würde ich gesetzt den Wert der Schlüssel c-$v so dass

print Dumper $hash; 

die Änderung widerspiegeln würde:

Jetzt bekommen könnte der Wert wie folgt durchgeführt werden ? $h ist kein Ref am Ende der foreach-Schleife, so dass das Ändern nicht die Änderung in $hash widerspiegelt. Irgendwelche Hinweise, wie ich die Knoten in meinem Kopf lösen kann?

Answer 1

Etwas wie folgt aus:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

der letzte Schlüssel ist popping out für wusses! ;)

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

Eine mächtige (und damit etwas schwieriger zu benutzen) Version dieser Funktion wird durch Data::Diver zur Verfügung gestellt.

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(daxim die Nutzung ist leicht ab.)