XSLT Kopie derselben Geschwister, bis andere Geschwister erscheinen

Question

Hei,

ich bin trieing folgenden Liste Transformation mithilfe von XSLT 1.0:

<div data-class="a"> 
    <div data-class="b"/> 
    <div data-class="b"> 
     <div data-class="c"/> 
    </div> 
    <div data-class="b"/> 
</div> 
<div data-class="a"> 
    <div data-class="b"> 
     <div data-class="c"> 
      <div data-class="d"/> 
     </div> 
    </div> 
</div> 
<div data-class="a"/> 
<div data-class="a"/> 
    <div data-class="b"> 
     <div data-class="c"/> 
     <div data-class="c"/> 
    </div> 
</div> 

:

<div data-class="a"/> 
<div data-class="b"/> 
<div data-class="b"/> 
<div data-class="c"/> 
<div data-class="b"/> 
<div data-class="a"/> 
<div data-class="b"/> 
<div data-class="c"/> 
<div data-class="d"/> 
<div data-class="a"/> 
<div data-class="a"/> 

Es sollte die Daten wie folgt transformieren Ich versuche es seit Stunden richtig zu transformieren. es zu transformieren, ich die Kopie Tags bin mit:

<xsl:template match="node() | @*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node() | @*" /> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@data-class='a']"> 
    <xsl:copy> 
    <xsl:apply-templates select="node() | @* | following-sibling::div[@data-class='b']" /> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@data-class='a']"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()" /> 
    <xsl:apply-templates select="following-sibling::div[@data-class='b']" /> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@dataclass='b']"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()" /> 
    <xsl:apply-templates select="following-sibling::div[@data-class='c']" /> 
    </xsl:copy> 
</xsl:template> 

Das Problem ist, dass alle folgenden Elemente der Datenklasse getroffen werden - bitte helfen Sie mir. Vielen Dank!

Answer 1

Ich würde vorschlagen, dass Sie es so versuchen:

XSLT 1,0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="b" match="div[@data-class='b']" use="generate-id(preceding-sibling::div[@data-class='a'][1])" /> 
<xsl:key name="c" match="div[@data-class='c']" use="generate-id(preceding-sibling::div[@data-class='b'][1])" /> 
<xsl:key name="d" match="div[@data-class='d']" use="generate-id(preceding-sibling::div[@data-class='c'][1])" /> 

<!-- identity transform --> 
<xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="/root"> 
    <xsl:copy> 
     <xsl:apply-templates select="div[@data-class='a']"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@data-class='a']"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()" /> 
     <xsl:apply-templates select="key('b', generate-id())"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@data-class='b']"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()" /> 
    <xsl:apply-templates select="key('c', generate-id())"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="div[@data-class='c']"> 
    <xsl:copy> 
    <xsl:apply-templates select="@*|node()" /> 
    <xsl:apply-templates select="key('d', generate-id())"/> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

Wenn die oben auf die folgende wohlgeformte angelegt wird Eingabebeispiel:

XML

<root> 
    <div data-class="a"/> 
    <div data-class="b"/> 
    <div data-class="b"/> 
    <div data-class="c"/> 
    <div data-class="b"/> 
    <div data-class="a"/> 
    <div data-class="b"/> 
    <div data-class="c"/> 
    <div data-class="d"/> 
    <div data-class="a"/> 
    <div data-class="a"/> 
</root> 

das Ergebnis wird sein:

<?xml version="1.0" encoding="UTF-8"?> 
<root> 
    <div data-class="a"> 
     <div data-class="b"/> 
     <div data-class="b"> 
     <div data-class="c"/> 
     </div> 
     <div data-class="b"/> 
    </div> 
    <div data-class="a"> 
     <div data-class="b"> 
     <div data-class="c"> 
      <div data-class="d"/> 
     </div> 
     </div> 
    </div> 
    <div data-class="a"/> 
    <div data-class="a"/> 
</root>