Wie ein Ereignis mit zusätzlichen Daten versenden - AS3

Question

Kann jemand geben Sie mir ein einfaches Beispiel dafür, wie ein Ereignis in ActionScript3 mit einem Objekt mit ihm verbunden schicken, wie

dispatchEvent(new Event(GOT_RESULT,result)); 

Hier result ist ein Objekt, Ich möchte mit dem Event weitermachen.

Answer 1

Wenn Sie ein Objekt durch ein Ereignis übergeben möchten, sollten Sie ein benutzerdefiniertes Ereignis erstellen. Der Code sollte in etwa so sein.

public class MyEvent extends Event 
{ 
    public static const GOT_RESULT:String = "gotResult"; 

    // this is the object you want to pass through your event. 
    public var result:Object; 

    public function MyEvent(type:String, result:Object, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 
     this.result = result; 
    } 

    // always create a clone() method for events in case you want to redispatch them. 
    public override function clone():Event 
    { 
     return new MyEvent(type, result, bubbles, cancelable); 
    } 
} 

Dann können Sie den angezeigten Code wie folgt verwenden:

dispatchEvent(new MyEvent(MyEvent.GOT_RESULT, result)); 

Und Sie hören für diese Veranstaltung, wo nötig.

Answer 2

Bei richtiger Gestaltung sollten Sie kein Objekt an das Ereignis übergeben müssen.
Stattdessen sollten Sie eine öffentliche var auf der Dispatching-Klasse machen.

public var myObject:Object; 

// before you dispatch the event assign the object to your class var 
myObject = ....// whatever it is your want to pass 
// When you dispatch an event you can do it with already created events or like Tomislav wrote and create a custom class. 

// in the call back just use currentTarget 
public function myCallBackFunction(event:Event):void{ 

    // typecast the event target object 
    var myClass:myClassThatDispatchedtheEvent = event.currentTarget as myClassThatDispatchedtheEvent 
    trace(myClass.myObject)// the object or var you want from the dispatching class. 

Answer 3

Dieser Beitrag ist ein wenig alt, aber wenn es jemand helfen kann, können Sie Dataevent-Klasse wie so verwenden:

dispatchEvent(new DataEvent(YOUR_EVENT_ID, true, false, data)); 

Documentation