Beim Aufteilen der TXT-Datei durch Batch-Skript Ausrufe werden

Question

Ich bin neu zu Batch-Skript und hier habe ich versucht, meine Textdatei in Stücke für jede 1 Million Zeilen zu teilen. Chunk-Dateien werden wie erwartet generiert, aber innerhalb des Inhalts der Ausgabedatei fehlen die Ausrufe (!) Und sogar das Überspringen der unmittelbaren Spalte nach Exclamation. Bitte helfen Sie mir, Daten wie in der ursprünglichen Datei in Stücke zu bekommen!

@ECHO OFF 
setLocal DisableDelayedExpansion 

set limit=1000000 
set feed_name=test.txt 
set file=%Tgt_Dir%\%feed_name% 
set lineCounter=1 
set filenameCounter=1 
set name= 
set extension= 


for %%a in (%file%) do (
    set "name=%%~na" 
    set "extension=%%~xa" 
) 

setlocal enabledelayedexpansion 
for /f "tokens=*" %%a in (%file%) do (
    set splitFile=!name!%date:~12,2%%date:~4,2%%date:~7,2%!filenameCounter!!extension! 
    if !lineCounter! gtr !limit! (
     set /a filenameCounter=!filenameCounter! + 1 
     set lineCounter=1 
     echo Created !splitFile!. 
    ) 
    echo %%a>> %Tgt_Dir%\!splitFile! 

    set /a lineCounter=!lineCounter! + 1 
) 
endlocal 

Es ist eine Tab-Delimiter-Datei.

ScreenShot

Answer 1

Sie müssen verzögerte Expansion wechseln.

setlocal DisableDelayedExpansion 
for /f "tokens=*" %%a in (%file%) do (
    Set "line=%%a" 
    setlocal EnableDelayedExpansion 

     set splitFile=!name!%date:~12,2%%date:~4,2%%date:~7,2%!filenameCounter!!extension! 

     echo(!line!>> %Tgt_Dir%\!splitFile! 

    if !lineCounter! gtr !limit! (
     ENDLOCAL 
     set /a filenameCounter+=1 
     set lineCounter=1 
     echo Created file 
    ) ELSE ENDLOCAL 
    set /a lineCounter=lineCounter + 1 
)