VBA: Verwenden Sie Textfeld, um List-Feld auf Word-Benutzerformular aufzufüllen - Abfrage-Excel-Datenbank

Question

Ich möchte ein List-Feld auf einem Word-Benutzerformular basierend auf den Daten, die in einem Textfeld in demselben Formular eingegeben werden, füllen. Im Idealfall würde dies in Echtzeit geschehen (mit dem Änderungsereignis, das ich denke), wobei jedes Zeichen, das in das Textfeld eingegeben wurde, die im Listenfeld angezeigten Elemente filtert.

Die Datenquelle ist eine Excel "Datenbank", auf die mit DAO zugegriffen wird. Der folgende Code funktioniert, aber er trägt die gesamte Datenbank in Listenfeld ein (basierend darauf - Link).

Private Sub UserForm_Initialize() 

    Dim db As DAO.Database 
    Dim rs As DAO.Recordset 
    Dim NoOfRecords As Long 

    'Open the database (Excel File) 
    Set db = OpenDatabase("C:\Users\T400\Documents\UserFormListTest.xlsx" _ 
      , False, False, "Excel 8.0") 

    'Retrieve the recordset > Excel Range = "ListBoxData" 
    Set rs = db.OpenRecordset("SELECT * FROM ListBoxData") 

    ' Determine the number of retrieved records 
    With rs 
     .MoveLast 
      NoOfRecords = .RecordCount 
     .MoveFirst 
    End With 

    ' Set the number of Columns = number of Fields in recordset 
    ListBox1.ColumnCount = rs.Fields.Count 
    ListBox1.Column = rs.GetRows(NoOfRecords) 

     rs.Close 
     db.Close 

     Set rs = Nothing 
     Set db = Nothing 

    End Sub 

Wie kann ich die Daten filtern, so dass das Listenfeld nur für das Textfeld ausgefüllt wird? Ich habe auf eine einfache Lösung gehofft, wie zum Beispiel die Modifikation des SELECT * Abfrageteils des Codes.

Ist das möglich? Oder gibt es einen besseren Weg?

Answer 1

Wie ich im Kommentar zu der Frage erwähnt, verwendet MS Excel Jet-Datenbank-Engine. Sie müssen also Platzhalter verwenden, die dieser Datenbank-Engine entsprechen. All, StartsWith, Contains und EndsWith:

Also, wenn Sie benutzerdefinierte entwickeln wollen „Suche/finden“ Funktionalität, können Sie Combobox Steuerelement auf dem Formular mit diesen Optionen hinzuzufügen. Ein Beispielcode sollte wie folgt aussehen (die Namen der Kontrollen zu Ihnen ersetzen):

Dim sName As String 
Dim sSearchType As String 
Dim sQry As String 

sName = TextBox1.Text 
sSearchType = ComboBox1.Value 

sQry = "SELECT * FROM ListBoxData " 
Select Case sSearchType 
    Case "All" 
     'do nothing; return all records 
    Case "StartsWith" 
     sQry = sQry & "WHERE Name Like '" & sName & "*'" 
    Case "Contains" 
     sQry = sQry & "WHERE Name Like '*" & sName & "*'" 
    Case "EndWith" 
     sQry = sQry & "WHERE Name Like '*" & sName & "'" 
End Select 

Set rs = db.OpenRecordset(sQry) 
'other stuff 

Mehr über Platzhalter, finden Sie hier:
Access wildcard character reference
Office: Wildcard Characters used in String Comparisons