Wie ignoriert man Timer-Ereignisse in Delphis MessageDlg

Question

Ich habe einen globalen Ausnahme-Handler in Delphi eingerichtet. Bei einigen schweren Ausnahmen wird eine Fehlermeldung angezeigt (gefolgt von Halt()). Während die Fehlermeldung angezeigt wird, verarbeitet Delphi die Nachrichtenwarteschlange und verarbeitet Timer-Ereignisse, die zu weiteren Fehlern führen.

Was ich will, ist ein Fehlerdialog anzuzeigen, der Timer-Ereignisse nicht verarbeitet. Wie ist das in Delphi möglich?

Bearbeiten: Ich benutze Dialogs.MessageDlg (...), um die Nachricht anzuzeigen.

Answer 1

Sie können Nachrichten in der Warteschlange filtern, wie WM_TIMER, mit TApplication.OnMessage.

procedure TMainForm.ApplicationMessage(var Msg: TMsg; var Handled: Boolean); 
begin 
    if ShowingFatalErrorDialog then 
    if Msg.Message = WM_TIMER then 
     Handled := True; 
end; 

Entweder das Ereignisbehandlungsroutine direkt zu Application.OnMessage zuweisen oder ein TApplicationEvents Objekt verwenden.

Offensichtlich müssen Sie die Implementierung für ShowingFatalErrorDialog bereitstellen, aber ich vertraue darauf, dass es für Sie offensichtlich ist, wie Sie dies tun.

Answer 2

versuchen, etwas wie folgt aus:

... 
    private 
    FAboutToTerminate: Boolean; 
    end; 

... 

type 
    ESevereError = class(Exception); 

procedure TForm1.Timer1Timer(Sender: TObject); 
begin 
    Tag := Tag + 1; 
    if Tag > 2 then 
    raise ESevereError.Create('Error'); 
end; 

procedure TForm1.ApplicationEvents1Exception(Sender: TObject; 
    E: Exception); 
begin 
    if (E is ESevereError) and (not FAboutToTerminate) then 
    begin 
    FAboutToTerminate := True; 
    Application.ShowException(E); 
    Application.Terminate; 
    end; 
end; 

Answer 3

Nur als Referenz: Ich werde den folgenden Code verwenden, der eine Mischung aus beiden Antworten ist.

procedure SaveShowErrorMessage(...) 
begin 
    with TFatalErrorAppEvents.Create(nil) do //avoid timer and further exceptions 
    try 
     Dialogs.MessageDlg(...); 
    finally 
     Free; 
    end; 
end; 

Mit TFatalErrorAppEvents wie folgt:

type 
    TFatalErrorAppEvents = class(TApplicationEvents) 
    protected 
     procedure KillTimerMessages(var Msg: tagMSG; var Handled: Boolean); 
     procedure IgnoreAllExceptions(Sender: TObject; E: Exception); 
    public 
     constructor Create(AOwner: TComponent); override; 
    end; 


constructor TFatalErrorAppEvents.Create(AOwner: TComponent); 
begin 
    inherited; 
    OnMessage := KillTimerMessages; 
    OnException := IgnoreAllExceptions; 
end; 

procedure TFatalErrorAppEvents.IgnoreAllExceptions(Sender: TObject; E: Exception); 
begin 
    //in case of an Exception do nothing here to ignore the exception 
end; 

procedure TFatalErrorAppEvents.KillTimerMessages(var Msg: tagMSG; var Handled: Boolean); 
begin 
    if (Msg.message = WM_TIMER) then 
     Handled := True; 
end;