vb.net Screen Capture von form2 mit form1

Question

Ich habe ein Problem hier. Ich habe eine Form1, die ich verwende, um Einstellungen zu erhalten. Aber es gibt auch ein Panel, das ich verwenden möchte, um zu sehen, was in Form2 ist.

Form2 = eine Vollbild-Form ohne formborderstyles

Diese form2 zeigt Informationen auf einem großen Bildschirm und ich brauche in meinem form1 (in diesem Panel), um den gesamten Inhalt form2 wie eine Screencapture Sache zu sehen.

Kann jemand helfen?

Answer 1

A -Panel wird Flackern Probleme in Windows produzieren, empfehle ich Ihnen einen PictureBox zu platzieren innerhalb des -Panel mit dem PictureBox.Dock = Fill Objekt (oder benutzen Sie einfach nur die PictureBox anstelle eines -Panel) dann könnten Sie zum Beispiel meine TakeScreenshotFromForm() Funktion von meinem ElektroKit Framework verwenden.

Ein voll funktionierendes Beispiel:

Imports System.Drawing.Drawing2D 
Imports System.Drawing.Imaging 

Public Class Form1 : Inherits Form 

    Friend WithEvents ScreenshotTimer As New System.Windows.Forms.Timer 

    Private Sub Test() Handles MyBase.Shown 

     Form2.Show() 

     With Me.ScreenshotTimer 
      .Interval = 100 
      .Enabled = True 
      .Start() 
     End With 

     Me.PictureBox1.BackgroundImageLayout = ImageLayout.Stretch 

    End Sub 

    Private Sub ScreenshotTimer_Tick(sender As Object, e As EventArgs) Handles ScreenshotTimer.Tick 

     If Me.PictureBox1.BackgroundImage IsNot Nothing Then 
      Me.PictureBox1.BackgroundImage.Dispose() 
     End If 

     Me.PictureBox1.BackgroundImage = TakeScreenshotFromForm(Form2, includeMouse:=True) 

    End Sub 

    Public Shared Function TakeScreenshotFromForm(ByVal f As Form, 
                Optional ByVal includeMouse As Boolean = False, 
                Optional ByVal pixelFormat As PixelFormat = PixelFormat.Format24bppRgb) As Image 

     If Not f.Visible Then 
      Return Nothing 
     End If 

     Dim bmp As New Bitmap(f.Size.Width, f.Size.Height, pixelFormat) 

     Using g As Graphics = Graphics.FromImage(bmp) 

      g.InterpolationMode = InterpolationMode.Default 
      g.PixelOffsetMode = PixelOffsetMode.Default 
      g.CopyFromScreen(f.Location, New Drawing.Point(0, 0), f.Size) 

      ' Draw the cursor in the image. 
      If includeMouse Then 

       Dim cursorSize As System.Drawing.Size = CType(f.Cursor.HotSpot, System.Drawing.Size) 
       cursorSize.Width -= ((f.Size.Width - f.ClientSize.Width) \ 2) 
       cursorSize.Height -= ((f.Size.Height - f.ClientSize.Height) - ((f.Size.Width - f.ClientSize.Width) \ 2)) 

       Dim formPoint As Drawing.Point = f.PointToClient(Drawing.Point.Subtract(Control.MousePosition, cursorSize)) 

       Cursors.Arrow.Draw(g, New Rectangle(formPoint.X, formPoint.Y, cursorSize.Width, cursorSize.Height)) 

      End If 

     End Using 

     Return bmp 

    End Function 

End Class 

Anstelle der Methodik, die ich verwenden, können Sie auch die Control.DrawToBitmap() Methode verwenden properlly das Formular zu erfassen, wenn ist nicht sichtbar (auf dem Bildschirm völlig unsichtbar oder von anderen Fenstern abgedeckt), aber das resultierende Bild enthält keine "Informationen" wie z TextBox Caret zum Beispiel.

Dim bmp As New Bitmap(f.Bounds.Size.Width, f.Bounds.Size.Height, pixelFormat) 
f.DrawToBitmap(bmp, New Rectangle(0, 0, f.Bounds.Size.Width, f.Bounds.Size.Height)) 
' ...