Erstellen Sie msgbox beim Ausführen von Batch

Question

Ich brauche jedes, um seine eigene Message-Box zu knacken, wenn ich auf OK klicke, bewegt es sich zum nächsten und dann zum nächsten. Am Ende speichert es alles als Textdokument auf dem Desktop. Wird derzeit in einer .bat verwendet, aber wenn .vbs wäre einfacher oder besser sagen Sie mir bitte, welchen Code zu verwenden.

Ich habe versucht, einschließlich msgbox, aber nicht sicher, wie Sie die verschiedenen Codes mit jeder Box einstellen. Ich habe versucht, Reverse-Engineer: Set WshShell = CreateObject ("WScript.Shell") MsgBox ConvertToKey (WshShell.RegRead ("HKLM \ SOFTWARE \ Microsoft \ Windows NT \ CurrentVersion \ DigitalProductId") Aber kein solches Glück

Answer 1

Versuchen Sie wie auf diese Weise:

@echo off 
Set Title="Example of MsgBox by Hackoo" 
Set TmpFile=Tmp.txt 
Set LogFile=%UserProfile%\Desktop\result.txt 
(
    for /f "delims=" %%G in ('wmic csproduct get uuid') do (echo "%%G" & Call:MsgBox "%%G" ,vbInformation,%Title%) 
    for /f "delims=" %%G in ('wmic diskdrive get SerialNumber') do (echo "%%G" & Call:MsgBox "%%G" ,vbInformation,%Title%) 
    for /f "delims=" %%G in ('getmac') do (echo %%G & Call:MsgBox "%%G" ,vbInformation,%Title%) 
)>%TmpFile% 
Cmd /U /C Type %TmpFile% > %LogFile% 
Start "" %LogFile% 
Del %TmpFile% 
Exit /b 

:MsgBox <Message> <Buttons Type> <Title> 
Rem This function create a vbscript file %tmp%\Msg.vbs with 3 arguments and executes it 
Rem First argument is %1 ==> To show the message 
Rem Second argument is %2 ==> To choose the type of buttons 
Rem Third argument is %3 ==> To show the Title 
Rem Example how we can call this function : 
Rem Call :MsgBox "This an example from Hackoo to say Hello to ""stackoverflow.com"" ",vbInformation,%Title% 
Rem Call :MsgBox "This an example from Hackoo to show any kind of a Warning Message",vbExclamation,%Title% 
Rem Call :MsgBox "This an example from Hackoo to show any kind of error",vbCritical,%Title% 
(
echo MsgBox %1,%2,%3 
)>%tmp%\Msg.vbs 
cscript /nologo %tmp%\Msg.vbs 
Del %tmp%\Msg.vbs